| 1 | # JavaScriptCore - Qt4 build info
|
|---|
| 2 | VPATH += $$PWD
|
|---|
| 3 |
|
|---|
| 4 | INCLUDEPATH += tmp
|
|---|
| 5 | INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/bindings/qt $$PWD/wtf
|
|---|
| 6 | DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS
|
|---|
| 7 | DEFINES += BUILDING_QT__
|
|---|
| 8 |
|
|---|
| 9 | include(pcre/pcre.pri)
|
|---|
| 10 |
|
|---|
| 11 | LUT_FILES += \
|
|---|
| 12 | kjs/date_object.cpp \
|
|---|
| 13 | kjs/number_object.cpp \
|
|---|
| 14 | kjs/string_object.cpp \
|
|---|
| 15 | kjs/array_object.cpp \
|
|---|
| 16 | kjs/math_object.cpp \
|
|---|
| 17 | kjs/regexp_object.cpp
|
|---|
| 18 |
|
|---|
| 19 | KEYWORDLUT_FILES += \
|
|---|
| 20 | kjs/keywords.table
|
|---|
| 21 |
|
|---|
| 22 | KJSBISON += \
|
|---|
| 23 | kjs/grammar.y
|
|---|
| 24 |
|
|---|
| 25 | SOURCES += \
|
|---|
| 26 | wtf/TCSystemAlloc.cpp \
|
|---|
| 27 | wtf/Assertions.cpp \
|
|---|
| 28 | wtf/HashTable.cpp \
|
|---|
| 29 | wtf/FastMalloc.cpp \
|
|---|
| 30 | bindings/NP_jsobject.cpp \
|
|---|
| 31 | bindings/npruntime.cpp \
|
|---|
| 32 | bindings/runtime_array.cpp \
|
|---|
| 33 | bindings/runtime.cpp \
|
|---|
| 34 | bindings/runtime_method.cpp \
|
|---|
| 35 | bindings/runtime_object.cpp \
|
|---|
| 36 | bindings/runtime_root.cpp \
|
|---|
| 37 | bindings/c/c_class.cpp \
|
|---|
| 38 | bindings/c/c_instance.cpp \
|
|---|
| 39 | bindings/c/c_runtime.cpp \
|
|---|
| 40 | bindings/c/c_utility.cpp \
|
|---|
| 41 | bindings/qt/qt_class.cpp \
|
|---|
| 42 | bindings/qt/qt_instance.cpp \
|
|---|
| 43 | bindings/qt/qt_runtime.cpp \
|
|---|
| 44 | kjs/DateMath.cpp \
|
|---|
| 45 | kjs/JSWrapperObject.cpp \
|
|---|
| 46 | kjs/PropertyNameArray.cpp \
|
|---|
| 47 | kjs/array_object.cpp \
|
|---|
| 48 | kjs/bool_object.cpp \
|
|---|
| 49 | kjs/collector.cpp \
|
|---|
| 50 | kjs/Context.cpp \
|
|---|
| 51 | kjs/date_object.cpp \
|
|---|
| 52 | kjs/debugger.cpp \
|
|---|
| 53 | kjs/dtoa.cpp \
|
|---|
| 54 | kjs/error_object.cpp \
|
|---|
| 55 | kjs/ExecState.cpp \
|
|---|
| 56 | kjs/fpconst.cpp \
|
|---|
| 57 | kjs/function.cpp \
|
|---|
| 58 | kjs/function_object.cpp \
|
|---|
| 59 | kjs/identifier.cpp \
|
|---|
| 60 | kjs/internal.cpp \
|
|---|
| 61 | kjs/interpreter.cpp \
|
|---|
| 62 | kjs/JSImmediate.cpp \
|
|---|
| 63 | kjs/JSLock.cpp \
|
|---|
| 64 | kjs/lexer.cpp \
|
|---|
| 65 | kjs/list.cpp \
|
|---|
| 66 | kjs/lookup.cpp \
|
|---|
| 67 | kjs/math_object.cpp \
|
|---|
| 68 | kjs/nodes.cpp \
|
|---|
| 69 | kjs/nodes2string.cpp \
|
|---|
| 70 | kjs/number_object.cpp \
|
|---|
| 71 | kjs/object.cpp \
|
|---|
| 72 | kjs/object_object.cpp \
|
|---|
| 73 | kjs/operations.cpp \
|
|---|
| 74 | kjs/Parser.cpp \
|
|---|
| 75 | kjs/property_map.cpp \
|
|---|
| 76 | kjs/property_slot.cpp \
|
|---|
| 77 | kjs/regexp.cpp \
|
|---|
| 78 | kjs/regexp_object.cpp \
|
|---|
| 79 | kjs/scope_chain.cpp \
|
|---|
| 80 | kjs/string_object.cpp \
|
|---|
| 81 | kjs/ustring.cpp \
|
|---|
| 82 | kjs/value.cpp
|
|---|
| 83 |
|
|---|
| 84 |
|
|---|
| 85 | # GENERATOR 1-A: LUT creator
|
|---|
| 86 | lut.output = tmp/${QMAKE_FILE_BASE}.lut.h
|
|---|
| 87 | lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
|
|---|
| 88 | lut.depend = ${QMAKE_FILE_NAME}
|
|---|
| 89 | lut.input = LUT_FILES
|
|---|
| 90 | lut.CONFIG += no_link
|
|---|
| 91 | QMAKE_EXTRA_COMPILERS += lut
|
|---|
| 92 |
|
|---|
| 93 | # GENERATOR 1-B: particular LUT creator (for 1 file only)
|
|---|
| 94 | keywordlut.output = tmp/lexer.lut.h
|
|---|
| 95 | keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
|
|---|
| 96 | keywordlut.depend = ${QMAKE_FILE_NAME}
|
|---|
| 97 | keywordlut.input = KEYWORDLUT_FILES
|
|---|
| 98 | keywordlut.CONFIG += no_link
|
|---|
| 99 | QMAKE_EXTRA_COMPILERS += keywordlut
|
|---|
| 100 |
|
|---|
| 101 | # GENERATOR 2: bison grammar
|
|---|
| 102 | kjsbison.output = tmp/${QMAKE_FILE_BASE}.cpp
|
|---|
| 103 | kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && mv ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && mv ${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h
|
|---|
| 104 | kjsbison.depend = ${QMAKE_FILE_NAME}
|
|---|
| 105 | kjsbison.input = KJSBISON
|
|---|
| 106 | kjsbison.variable_out = GENERATED_SOURCES
|
|---|
| 107 | kjsbison.dependency_type = TYPE_C
|
|---|
| 108 | kjsbison.CONFIG = target_predeps
|
|---|
| 109 | kjsbison.clean = ${QMAKE_FILE_OUT} tmp/${QMAKE_FILE_BASE}.h
|
|---|
| 110 | QMAKE_EXTRA_COMPILERS += kjsbison
|
|---|
