| 1 | # JavaScriptCore - Qt4 build info
|
|---|
| 2 | VPATH += $$PWD
|
|---|
| 3 |
|
|---|
| 4 | INCLUDEPATH += tmp
|
|---|
| 5 | INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/wtf $$PWD/wtf/unicode $$PWD/VM
|
|---|
| 6 | DEPENDPATH += $$PWD $$PWD/kjs $$PWD/wtf $$PWD/wtf/unicode $$PWD/VM
|
|---|
| 7 | DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS
|
|---|
| 8 | DEFINES += BUILDING_QT__
|
|---|
| 9 |
|
|---|
| 10 | win32-msvc*: INCLUDEPATH += $$PWD/os-win32
|
|---|
| 11 |
|
|---|
| 12 | isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
|
|---|
| 13 |
|
|---|
| 14 | include(pcre/pcre.pri)
|
|---|
| 15 |
|
|---|
| 16 | LUT_FILES += \
|
|---|
| 17 | kjs/date_object.cpp \
|
|---|
| 18 | kjs/number_object.cpp \
|
|---|
| 19 | kjs/string_object.cpp \
|
|---|
| 20 | kjs/array_object.cpp \
|
|---|
| 21 | kjs/math_object.cpp \
|
|---|
| 22 | kjs/regexp_object.cpp
|
|---|
| 23 |
|
|---|
| 24 | KEYWORDLUT_FILES += \
|
|---|
| 25 | kjs/keywords.table
|
|---|
| 26 |
|
|---|
| 27 | KJSBISON += \
|
|---|
| 28 | kjs/grammar.y
|
|---|
| 29 |
|
|---|
| 30 | SOURCES += \
|
|---|
| 31 | wtf/Assertions.cpp \
|
|---|
| 32 | wtf/HashTable.cpp \
|
|---|
| 33 | wtf/MainThread.cpp \
|
|---|
| 34 | wtf/unicode/CollatorDefault.cpp \
|
|---|
| 35 | wtf/unicode/icu/CollatorICU.cpp \
|
|---|
| 36 | wtf/unicode/UTF8.cpp \
|
|---|
| 37 | API/JSBase.cpp \
|
|---|
| 38 | API/JSCallbackConstructor.cpp \
|
|---|
| 39 | API/JSCallbackFunction.cpp \
|
|---|
| 40 | API/JSCallbackObject.cpp \
|
|---|
| 41 | API/JSClassRef.cpp \
|
|---|
| 42 | API/JSContextRef.cpp \
|
|---|
| 43 | API/JSObjectRef.cpp \
|
|---|
| 44 | API/JSStringRef.cpp \
|
|---|
| 45 | API/JSValueRef.cpp \
|
|---|
| 46 | kjs/InitializeThreading.cpp \
|
|---|
| 47 | kjs/JSGlobalObject.cpp \
|
|---|
| 48 | kjs/JSVariableObject.cpp \
|
|---|
| 49 | kjs/JSActivation.cpp \
|
|---|
| 50 | kjs/JSNotAnObject.cpp \
|
|---|
| 51 | VM/CodeBlock.cpp \
|
|---|
| 52 | VM/CodeGenerator.cpp \
|
|---|
| 53 | VM/ExceptionHelpers.cpp \
|
|---|
| 54 | VM/Instruction.cpp \
|
|---|
| 55 | VM/JSPropertyNameIterator.cpp \
|
|---|
| 56 | VM/LabelID.cpp \
|
|---|
| 57 | VM/Machine.cpp \
|
|---|
| 58 | VM/Opcode.cpp \
|
|---|
| 59 | VM/Register.cpp \
|
|---|
| 60 | VM/RegisterFile.cpp \
|
|---|
| 61 | VM/RegisterFileStack.cpp \
|
|---|
| 62 | VM/RegisterID.cpp
|
|---|
| 63 |
|
|---|
| 64 | # AllInOneFile.cpp helps gcc analize and optimize code
|
|---|
| 65 | # Other compilers may be able to do this at link time
|
|---|
| 66 | SOURCES += \
|
|---|
| 67 | kjs/function.cpp \
|
|---|
| 68 | kjs/debugger.cpp \
|
|---|
| 69 | kjs/array_instance.cpp \
|
|---|
| 70 | kjs/array_object.cpp \
|
|---|
| 71 | kjs/bool_object.cpp \
|
|---|
| 72 | kjs/collector.cpp \
|
|---|
| 73 | kjs/CommonIdentifiers.cpp \
|
|---|
| 74 | kjs/date_object.cpp \
|
|---|
| 75 | kjs/DateMath.cpp \
|
|---|
| 76 | kjs/DebuggerCallFrame.cpp \
|
|---|
| 77 | kjs/dtoa.cpp \
|
|---|
| 78 | kjs/error_object.cpp \
|
|---|
| 79 | kjs/ExecState.cpp \
|
|---|
| 80 | kjs/function_object.cpp \
|
|---|
| 81 | kjs/identifier.cpp \
|
|---|
| 82 | kjs/internal.cpp \
|
|---|
| 83 | kjs/interpreter.cpp \
|
|---|
| 84 | kjs/JSImmediate.cpp \
|
|---|
| 85 | kjs/JSLock.cpp \
|
|---|
| 86 | kjs/JSWrapperObject.cpp \
|
|---|
| 87 | kjs/lexer.cpp \
|
|---|
| 88 | kjs/list.cpp \
|
|---|
| 89 | kjs/lookup.cpp \
|
|---|
| 90 | kjs/math_object.cpp \
|
|---|
| 91 | kjs/nodes.cpp \
|
|---|
| 92 | kjs/nodes2string.cpp \
|
|---|
| 93 | kjs/number_object.cpp \
|
|---|
| 94 | kjs/object.cpp \
|
|---|
| 95 | kjs/object_object.cpp \
|
|---|
| 96 | kjs/operations.cpp \
|
|---|
| 97 | kjs/Parser.cpp \
|
|---|
| 98 | kjs/property_map.cpp \
|
|---|
| 99 | kjs/property_slot.cpp \
|
|---|
| 100 | kjs/PropertyNameArray.cpp \
|
|---|
| 101 | kjs/regexp.cpp \
|
|---|
| 102 | kjs/regexp_object.cpp \
|
|---|
| 103 | kjs/scope_chain.cpp \
|
|---|
| 104 | kjs/string_object.cpp \
|
|---|
| 105 | kjs/ustring.cpp \
|
|---|
| 106 | kjs/value.cpp \
|
|---|
| 107 | profiler/ProfileNode.cpp \
|
|---|
| 108 | profiler/Profile.cpp \
|
|---|
| 109 | profiler/Profiler.cpp \
|
|---|
| 110 | wtf/FastMalloc.cpp \
|
|---|
| 111 | wtf/ThreadingQt.cpp \
|
|---|
| 112 | wtf/qt/MainThreadQt.cpp
|
|---|
| 113 |
|
|---|
| 114 | !CONFIG(QTDIR_build) {
|
|---|
| 115 | defineTest(addExtraCompiler) {
|
|---|
| 116 | QMAKE_EXTRA_COMPILERS += $$1
|
|---|
| 117 | generated_files.depends += compiler_$${1}_make_all
|
|---|
| 118 | export(QMAKE_EXTRA_COMPILERS)
|
|---|
| 119 | export(generated_files.depends)
|
|---|
| 120 | return(true)
|
|---|
| 121 | }
|
|---|
| 122 | }
|
|---|
| 123 |
|
|---|
| 124 | # GENERATOR 1-A: LUT creator
|
|---|
| 125 | lut.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.lut.h
|
|---|
| 126 | lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
|
|---|
| 127 | lut.depend = ${QMAKE_FILE_NAME}
|
|---|
| 128 | lut.input = LUT_FILES
|
|---|
| 129 | lut.CONFIG += no_link
|
|---|
| 130 | addExtraCompiler(lut)
|
|---|
| 131 |
|
|---|
| 132 | # GENERATOR 1-B: particular LUT creator (for 1 file only)
|
|---|
| 133 | keywordlut.output = $$GENERATED_SOURCES_DIR/lexer.lut.h
|
|---|
| 134 | keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
|
|---|
| 135 | keywordlut.depend = ${QMAKE_FILE_NAME}
|
|---|
| 136 | keywordlut.input = KEYWORDLUT_FILES
|
|---|
| 137 | keywordlut.CONFIG += no_link
|
|---|
| 138 | addExtraCompiler(keywordlut)
|
|---|
| 139 |
|
|---|
| 140 | # GENERATOR 2: bison grammar
|
|---|
| 141 | kjsbison.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.cpp
|
|---|
| 142 | kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && $(MOVE) ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && $(MOVE) ${QMAKE_FILE_BASE}.tab.h $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.h
|
|---|
| 143 | kjsbison.depend = ${QMAKE_FILE_NAME}
|
|---|
| 144 | kjsbison.input = KJSBISON
|
|---|
| 145 | kjsbison.variable_out = GENERATED_SOURCES
|
|---|
| 146 | kjsbison.dependency_type = TYPE_C
|
|---|
| 147 | kjsbison.CONFIG = target_predeps
|
|---|
| 148 | kjsbison.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_GENERATED_SOURCES_DIR}${QMAKE_FILE_BASE}.h
|
|---|
| 149 | addExtraCompiler(kjsbison)
|
|---|
