| 1 | # JavaScriptCore - qmake build info
|
|---|
| 2 | CONFIG += building-libs
|
|---|
| 3 | include($$PWD/../WebKit.pri)
|
|---|
| 4 |
|
|---|
| 5 | TEMPLATE = lib
|
|---|
| 6 | CONFIG += staticlib
|
|---|
| 7 | TARGET = JavaScriptCore
|
|---|
| 8 |
|
|---|
| 9 | CONFIG += depend_includepath
|
|---|
| 10 |
|
|---|
| 11 | contains(QT_CONFIG, embedded):CONFIG += embedded
|
|---|
| 12 |
|
|---|
| 13 | CONFIG(QTDIR_build) {
|
|---|
| 14 | GENERATED_SOURCES_DIR = $$PWD/generated
|
|---|
| 15 | OLDDESTDIR = $$DESTDIR
|
|---|
| 16 | include($$QT_SOURCE_TREE/src/qbase.pri)
|
|---|
| 17 | DESTDIR = $$OLDDESTDIR
|
|---|
| 18 | PRECOMPILED_HEADER = $$PWD/../WebKit/qt/WebKit_pch.h
|
|---|
| 19 | DEFINES *= NDEBUG
|
|---|
| 20 | }
|
|---|
| 21 |
|
|---|
| 22 | isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
|
|---|
| 23 | GENERATED_SOURCES_DIR_SLASH = $$GENERATED_SOURCES_DIR/
|
|---|
| 24 | win32-*: GENERATED_SOURCES_DIR_SLASH ~= s|/|\|
|
|---|
| 25 |
|
|---|
| 26 | INCLUDEPATH += $$GENERATED_SOURCES_DIR
|
|---|
| 27 |
|
|---|
| 28 | !CONFIG(QTDIR_build) {
|
|---|
| 29 | OBJECTS_DIR = tmp
|
|---|
| 30 | }
|
|---|
| 31 |
|
|---|
| 32 | include($$OUTPUT_DIR/config.pri)
|
|---|
| 33 |
|
|---|
| 34 | CONFIG -= warn_on
|
|---|
| 35 | *-g++*:QMAKE_CXXFLAGS += -Wreturn-type -fno-strict-aliasing
|
|---|
| 36 | #QMAKE_CXXFLAGS += -Wall -Wno-undef -Wno-unused-parameter
|
|---|
| 37 |
|
|---|
| 38 | CONFIG(release):!CONFIG(QTDIR_build) {
|
|---|
| 39 | contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
|
|---|
| 40 | unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
|
|---|
| 41 | }
|
|---|
| 42 |
|
|---|
| 43 | linux-*: DEFINES += HAVE_STDINT_H
|
|---|
| 44 | freebsd-*: DEFINES += HAVE_PTHREAD_NP_H
|
|---|
| 45 |
|
|---|
| 46 | DEFINES += BUILD_WEBKIT
|
|---|
| 47 |
|
|---|
| 48 | # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
|
|---|
| 49 | win32-g++ {
|
|---|
| 50 | TMPPATH = $$quote($$(INCLUDE))
|
|---|
| 51 | QMAKE_INCDIR_POST += $$split(TMPPATH,";")
|
|---|
| 52 | TMPPATH = $$quote($$(LIB))
|
|---|
| 53 | QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
|
|---|
| 54 | }
|
|---|
| 55 |
|
|---|
| 56 | DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1
|
|---|
| 57 |
|
|---|
| 58 | DEFINES += WTF_CHANGES=1
|
|---|
| 59 |
|
|---|
| 60 | include(JavaScriptCore.pri)
|
|---|
| 61 |
|
|---|
| 62 | QMAKE_EXTRA_TARGETS += generated_files
|
|---|
| 63 |
|
|---|
| 64 | qt-port: lessThan(QT_MINOR_VERSION, 4) {
|
|---|
| 65 | DEFINES += QT_BEGIN_NAMESPACE="" QT_END_NAMESPACE=""
|
|---|
| 66 | }
|
|---|
