| 1 | # JavaScriptCore - qmake build info
|
|---|
| 2 | CONFIG += building-libs
|
|---|
| 3 | include($$PWD/../WebKit.pri)
|
|---|
| 4 |
|
|---|
| 5 | TEMPLATE = lib
|
|---|
| 6 | CONFIG += staticlib
|
|---|
| 7 | TARGET = JavaScriptCore
|
|---|
| 8 |
|
|---|
| 9 | CONFIG += depend_includepath
|
|---|
| 10 |
|
|---|
| 11 | contains(QT_CONFIG, embedded):CONFIG += embedded
|
|---|
| 12 |
|
|---|
| 13 | CONFIG(QTDIR_build) {
|
|---|
| 14 | GENERATED_SOURCES_DIR = $$PWD/generated
|
|---|
| 15 | OLDDESTDIR = $$DESTDIR
|
|---|
| 16 | include($$QT_SOURCE_TREE/src/qbase.pri)
|
|---|
| 17 | INSTALLS =
|
|---|
| 18 | DESTDIR = $$OLDDESTDIR
|
|---|
| 19 | PRECOMPILED_HEADER = $$PWD/../WebKit/qt/WebKit_pch.h
|
|---|
| 20 | DEFINES *= NDEBUG
|
|---|
| 21 | }
|
|---|
| 22 |
|
|---|
| 23 | isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
|
|---|
| 24 | GENERATED_SOURCES_DIR_SLASH = $$GENERATED_SOURCES_DIR/
|
|---|
| 25 | win32-*: GENERATED_SOURCES_DIR_SLASH ~= s|/|\|
|
|---|
| 26 |
|
|---|
| 27 | INCLUDEPATH += $$GENERATED_SOURCES_DIR
|
|---|
| 28 |
|
|---|
| 29 | !CONFIG(QTDIR_build) {
|
|---|
| 30 | CONFIG(debug, debug|release) {
|
|---|
| 31 | OBJECTS_DIR = obj/debug
|
|---|
| 32 | } else { # Release
|
|---|
| 33 | OBJECTS_DIR = obj/release
|
|---|
| 34 | }
|
|---|
| 35 | }
|
|---|
| 36 |
|
|---|
| 37 | include($$OUTPUT_DIR/config.pri)
|
|---|
| 38 |
|
|---|
| 39 | CONFIG -= warn_on
|
|---|
| 40 | *-g++*:QMAKE_CXXFLAGS += -Wreturn-type -fno-strict-aliasing
|
|---|
| 41 | #QMAKE_CXXFLAGS += -Wall -Wno-undef -Wno-unused-parameter
|
|---|
| 42 |
|
|---|
| 43 | CONFIG(release):!CONFIG(QTDIR_build) {
|
|---|
| 44 | contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
|
|---|
| 45 | unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
|
|---|
| 46 | }
|
|---|
| 47 |
|
|---|
| 48 | linux-*: DEFINES += HAVE_STDINT_H
|
|---|
| 49 | freebsd-*: DEFINES += HAVE_PTHREAD_NP_H
|
|---|
| 50 |
|
|---|
| 51 | DEFINES += BUILD_WEBKIT
|
|---|
| 52 |
|
|---|
| 53 | win32-*: DEFINES += _HAS_TR1=0
|
|---|
| 54 |
|
|---|
| 55 | # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
|
|---|
| 56 | win32-g++ {
|
|---|
| 57 | TMPPATH = $$quote($$(INCLUDE))
|
|---|
| 58 | QMAKE_INCDIR_POST += $$split(TMPPATH,";")
|
|---|
| 59 | TMPPATH = $$quote($$(LIB))
|
|---|
| 60 | QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
|
|---|
| 61 | }
|
|---|
| 62 |
|
|---|
| 63 | DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1
|
|---|
| 64 |
|
|---|
| 65 | DEFINES += WTF_CHANGES=1
|
|---|
| 66 |
|
|---|
| 67 | include(JavaScriptCore.pri)
|
|---|
| 68 |
|
|---|
| 69 | QMAKE_EXTRA_TARGETS += generated_files
|
|---|
| 70 |
|
|---|
| 71 | lessThan(QT_MINOR_VERSION, 4) {
|
|---|
| 72 | DEFINES += QT_BEGIN_NAMESPACE="" QT_END_NAMESPACE=""
|
|---|
| 73 | }
|
|---|
| 74 |
|
|---|
| 75 | *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
|
|---|
| 76 | *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3
|
|---|
