source: webkit/trunk/Source/JavaScriptCore/DerivedSources.pri@ 112454

Last change on this file since 112454 was 99274, checked in by [email protected], 14 years ago

[Qt] Refactor and clean up the qmake build system

The qmake build system has accumulated a bit of cruft and redundancy
over time. There's also a fairly tight coupling between how to build
the various targets, and _what_ to build, making it harder to add new
rules or sources. This patch aims to elevate these issues somewhat.

This is a short-list of the changes:

  • The rules for how to build targets are now mostly contained as prf-files in Tools/qmake/mkspecs/features. Using mkspecs also allows us to do pre- and post-processing of each project file, which helps to clean up the actual project files.
  • Derived sources are no longer generated as a separate make-step but is part of each target's project file as a subdir. Makefile rules are used to ensure that we run make on the derived sources before running qmake on the actual target makefile. This makes it easier to keep a proper dependency between derived sources and the target.
  • We use GNU make and the compiler to generate dependencies on UNIX-based systems running Qt 5. This allows us to lessen the need to run qmake, which should reduce compile time.
  • WebKit2 is now build by default if building with Qt 5. It can be disabled by passing --no-webkit2 to build-webkit.

The result of these changes are hopefully a cleaner and easier
build system to modify, and faster build times due to no longer
running qmake on every single build. It's also a first step
towards possibly generating the list of sources using another
build system.

​https://bugs.webkit.org/show_bug.cgi?id=71222

Reviewed by Simon Hausmann.
File size: 2.7 KB
Line 
1# -------------------------------------------------------------------
2# Derived sources for JavaScriptSource
3#
4# See 'Tools/qmake/README' for an overview of the build system
5# -------------------------------------------------------------------
6
7TEMPLATE = derived
8
9LUT_FILES += \
10 runtime/ArrayConstructor.cpp \
11 runtime/ArrayPrototype.cpp \
12 runtime/BooleanPrototype.cpp \
13 runtime/DateConstructor.cpp \
14 runtime/DatePrototype.cpp \
15 runtime/ErrorPrototype.cpp \
16 runtime/JSGlobalObject.cpp \
17 runtime/JSONObject.cpp \
18 runtime/MathObject.cpp \
19 runtime/NumberConstructor.cpp \
20 runtime/NumberPrototype.cpp \
21 runtime/ObjectConstructor.cpp \
22 runtime/ObjectPrototype.cpp \
23 runtime/RegExpConstructor.cpp \
24 runtime/RegExpObject.cpp \
25 runtime/RegExpPrototype.cpp \
26 runtime/StringConstructor.cpp \
27 runtime/StringPrototype.cpp \
28
29KEYWORDLUT_FILES += \
30 parser/Keywords.table
31
32JIT_STUB_FILES += \
33 jit/JITStubs.cpp
34
35# GENERATOR 1-A: LUT creator
36lut.output = ${QMAKE_FILE_BASE}.lut.h
37lut.input = LUT_FILES
38lut.script = $$PWD/create_hash_table
39lut.commands = perl $$lut.script ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
40lut.depends = ${QMAKE_FILE_NAME}
41GENERATORS += lut
42
43# GENERATOR 1-B: particular LUT creator (for 1 file only)
44keywordlut.output = Lexer.lut.h
45keywordlut.input = KEYWORDLUT_FILES
46keywordlut.script = $$PWD/create_hash_table
47keywordlut.commands = perl $$keywordlut.script ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
48keywordlut.depends = ${QMAKE_FILE_NAME}
49GENERATORS += keywordlut
50
51# GENERATOR 2-A: JIT Stub functions for RVCT
52rvctstubs.output = Generated${QMAKE_FILE_BASE}_RVCT.h
53rvctstubs.script = $$PWD/create_jit_stubs
54rvctstubs.commands = perl -i $$rvctstubs.script --prefix RVCT ${QMAKE_FILE_NAME} > ${QMAKE_FILE_OUT}
55rvctstubs.depends = ${QMAKE_FILE_NAME}
56rvctstubs.input = JIT_STUB_FILES
57rvctstubs.CONFIG += no_link
58GENERATORS += rvctstubs
59
60# GENERATOR 2-B: JIT Stub functions for MSVC
61msvcstubs.output = Generated${QMAKE_FILE_BASE}_MSVC.asm
62msvcstubs.script = $$PWD/create_jit_stubs
63msvcstubs.commands = perl -i $$msvcstubs.script --prefix MSVC ${QMAKE_FILE_NAME} > ${QMAKE_FILE_OUT}
64msvcstubs.depends = ${QMAKE_FILE_NAME}
65msvcstubs.input = JIT_STUB_FILES
66msvcstubs.CONFIG += no_link
67GENERATORS += msvcstubs
68
69#GENERATOR: "RegExpJitTables.h": tables used by Yarr
70retgen.output = RegExpJitTables.h
71retgen.script = $$PWD/create_regex_tables
72retgen.input = retgen.script
73retgen.commands = python $$retgen.script > ${QMAKE_FILE_OUT}
74GENERATORS += retgen
75
76#GENERATOR: "KeywordLookup.h": decision tree used by the lexer
77klgen.output = KeywordLookup.h
78klgen.script = $$PWD/KeywordLookupGenerator.py
79klgen.input = KEYWORDLUT_FILES
80klgen.commands = python $$klgen.script ${QMAKE_FILE_NAME} > ${QMAKE_FILE_OUT}
81GENERATORS += klgen
Note: See TracBrowser for help on using the repository browser.