Functions > Map >

MapRemove

Supprime une cl� et sa valeur dans une table.

MapRemove ( map, key )

Param�tres

map Une table existante
key La cl� � supprimer

Valeur de retour

Succ�s: Retourne 1
Echec: Retourne 0 et d�finit @error <> 0

Remarques

Presque uniquement dans AutoIt, les cl�s sont sensibles � la casse - "MyKey" n'est pas la m�me cl� que "mykey".

Les fonctions Map ne sont pas disponibles dans la version AutoIt 3.3.14.5 mais peuvent �tre test�es dans la version B�ta (Alt-F5).

En relation

MapAppend

Exemple

#include  <MsgBoxConstants.au3>

Example()

Func Example()
    ; D�clare une table et l'assigne avec des paires de cl�/valeur.
    Local $mMap[]
    $mMap["Jasper"] = "Jasper value"
    $mMap["Beethoven"] = "Beethoven value"
    $mMap["Pinky"] = "Pinky value"

    ; Lit les cl�s
    Local $aKeys = MapKeys($mMap)
    Local $sData = ""
    ; Lit les valeurs
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche le r�sultat
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

    ; Efface une cl� en la d�finissant � Null. La cl� existera encore dans la table.
    $mMap["Beethoven"] = Null

    ; Re-lit les cl�s et les valeurs
    $aKeys = MapKeys($mMap)
    $sData = ""
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche les valeurs des cl�s de la table. Notez que la cl� "Beethoven" contient maintenant une valeur vide (Null).
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

    ; Supprime la cl� "Beethoven" enti�rement.
    MapRemove($mMap, "Beethoven")

    ; Re-lit les cl�s et les valeurs
    $aKeys = MapKeys($mMap)
    $sData = ""
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche les valeurs des cl�s de la table. Notez que la cl� "Beethoven" n'existe plus.
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

EndFunc   ;==>Example