Option to specify default browser to display PlotlyLight.Plot() output

[StefanPofahl]

First of all, thank you for the nice package!
Here is my question:
How can I specify the default browser to display PlotlyLight.Plot() output?

For PlotlyJS.jl this can be achieved via the following lines in startup.jl

# --- redefine default browser for PlotlyJS: ---------------------------------------------------------------------------
using PlotlyJS
import PlotlyJS: PlotlyBase.launch_browser
launch_browser(tmppath::String) = run(`cmd /c start msedge.exe $tmppath`)

What would be the equivalent for PlotlyLight?

[joshday]

PlotlyLight relies on https://github.com/tpapp/DefaultApplication.jl to open the browser, but we could provide way to override it with your preferred command.

[joshday]

And I suppose this override should live in https://github.com/JuliaComputing/Cobweb.jl

[StefanPofahl]

Thanks for the fast reply! And which code snippets do you propose?

[joshday]

Looking into this a bit more, I don't think I want to add this as a feature. I'll close this issue, but there is quick workaround:

struct MyDisplay <: AbstractDisplay end

pushdisplay(MyDisplay())

function Base.display(::MyDisplay, page::Cobweb.Page) 
    filename = save(page)
    run(`<command to open filename in my browser of choice>`)
end

[StefanPofahl]

Thanks for the snippet!
For me, it is an important feature to define the default browser for my plots.
E.g. I do not like to browse the net with browser A but to display my plots with this browser is perfect.
Maybe you can add this snippet in your doc to your package.

P.S.:
Off-topic.
On Friday I worked with legend groups, to split the legend according to the two side-by-side subplots,
unfortunately, this broke the nice feature to toggle visibility of individual traces, would this be possible with your package?
here my example for PlotlyJS:

using PlotlyJS

function _legend_groups()
    # ---
    # --- create object containing sub-plots():
    _fig_obj = PlotlyJS.make_subplots(
        rows = 1, cols = 2,
    #           column 1    column 2
        specs = [ Spec()    Spec()], # raw 1
        )
    # --- read vector of standard colors "colorway":
    _colorway = PlotlyJS.PlotlyBase._get_colorway(_fig_obj.plot) # we must take the field ".plot"
    # ---
    _fig_layout = PlotlyJS.Layout(;
        title_text       = "Legend Groups",
        xaxis_title_text = "time / s",
        yaxis_title_text = "Amplitude",
        yaxis_range      = [0, 4],
        yaxis2 = PlotlyJS.attr(
            title       = "Amplitude",
            overlaying  = "y",
            side        = "left",
            range       = [0, 4],
            scaleanchor = "y",
            scaleratio  = 1,
        ),
        xaxis2_title_text = "time / s",
    )
    # ---
    for i_segment = 1 : 3
        if i_segment == 1
            PlotlyJS.add_trace!(_fig_obj, PlotlyJS.scatter(; y = i_segment .* ones(4), 
                line_color = _colorway[i_segment], 
                legendgroup = "group1", legendgrouptitle_text="First Group Title", ), row = 1, col =1)            
            PlotlyJS.add_trace!(_fig_obj, PlotlyJS.scatter(; y = 1.1 * i_segment .* ones(4), 
                line_color = _colorway[i_segment], 
                legendgroup = "group2", legendgrouptitle_text="Second Group Title", ), row = 1, col =2)            
        else
            PlotlyJS.add_trace!(_fig_obj, PlotlyJS.scatter(; y = i_segment .* ones(4), 
                line_color = _colorway[i_segment], legendgroup = "group1", ), row = 1, col =1)            
            PlotlyJS.add_trace!(_fig_obj, PlotlyJS.scatter(; y = 0.5 * i_segment .* ones(4), 
                line_color = _colorway[i_segment], legendgroup = "group2", ), row = 1, col = 2)
        end
    end
    # ---        
    PlotlyJS.relayout!(_fig_obj.plot, _fig_layout) # only re-layout the field ".plot"
    return _fig_obj
end
# ---
display(_legend_groups().plot)

[StefanPofahl]

Looking into this a bit more, I don't think I want to add this as a feature. I'll close this issue, but there is quick workaround:

struct MyDisplay <: AbstractDisplay end

pushdisplay(MyDisplay())

function Base.display(::MyDisplay, page::Cobweb.Page) 
    filename = save(page)
    run(`<command to open filename in my browser of choice>`)
end

What is wrong with my example?

using PlotlyLight, Cobweb
# ----------------------------------------------------------------------------------------------------------------------------------
# --- PlotlyLight Repository:   https://github.com/JuliaComputing/PlotlyLight.jl
# --- documentation:            https://plotly.com/javascript/
# include(raw"C:\data\git_repos\hycenta_stefan_pofahl\julia_scripts\examples\plotting\PlotlyLight\example_HelloWorld_PlotlyLight.jl")
# ----------------------------------------------------------------------------------------------------------------------------------
# --- proposal to make default browser selectable:
struct MyDisplay <: AbstractDisplay end

pushdisplay(MyDisplay())

function Base.display(::MyDisplay, page::Cobweb.Page) 
    _filename = save(page)
    @show _filename
    run(`cmd /c start msedge.exe $_filename`)
end

# --- Change template:
PlotlyLight.template!("plotly_dark")

# --- Make plot
# p = Plot(x = 1:20, y = cumsum(randn(20)), type="scatter", mode="lines+markers"); # this fails
# --- this works fine:
p = PlotlyLight.Plot(x = 1:20, y = cumsum(randn(20)), type="scatter", mode="lines+markers");

# Make changes
p.layout.title.text = "My Title!"

# `display(p)` to see the updated plot
display(p)

[joshday]

Sorry, I had a typo! This should be the method signature for display:

Base.display(::MyDisplay, ::PlotlyLight.Plot) 

julia> using PlotlyLight

julia> struct MyDisplay <: AbstractDisplay end

julia> pushdisplay(MyDisplay());

julia> function Base.display(::MyDisplay, ::Plot)
           @info "hi!"
       end

julia> Plot()
[ Info: hi!

---

Re: legend groups

If you have off-topic items to discuss, go ahead and make a new issue. The gist of it is that this package doesn't do much (on purpose). You should rely on Plotly's javascript documentation for everything. PlotlyLight just makes it easy to write Julia variables into Plotly's JSON specs.

[StefanPofahl]

Thanks! @info "hi!" works fine!
But how to catch the file name of the Plot-Output?

[joshday]

If you need the filename you should be saving the plot.

See: https://github.com/JuliaComputing/PlotlyLight.jl#-saving-plots

Although the "secret" location that the display mechanism uses is this file:

julia> joinpath(Cobweb.DIR, "index.html")
"/Users/joshday/.julia/scratchspaces/ec354790-cf28-43e8-bb59-b484409b7bad/CobWeb/index.html"

[joshday]

To clarify, every display that uses CobwebDisplay (what PlotlyLight uses) overwrites that index.html file and then opens it in browser.

[StefanPofahl]

Thanks! - Ok, if someone is reading this thread, here is a working example:

using PlotlyLight, Cobweb
# --- proposal to make default browser selectable:
struct MyDisplay <: AbstractDisplay end
pushdisplay(MyDisplay())
# ---
function Base.display(::MyDisplay, _myplot::PlotlyLight.Plot) 
    Cobweb.save(Cobweb.Page(_myplot)) # overwrite "index.html"
    _filename = joinpath(Cobweb.DIR, "index.html")
    run(`cmd /c start msedge.exe $_filename`) # put here the executable file of your preferred browser
end

# --- Start Plot Section: Change template:
PlotlyLight.template!("plotly_dark")

# --- Make plot
# p = Plot(x = 1:20, y = cumsum(randn(20)), type="scatter", mode="lines+markers"); # this fails
# --- this works fine:
p = PlotlyLight.Plot(x = 1:20, y = cumsum(randn(20)), type="scatter", mode="lines+markers");

# Make changes
p.layout.title.text = "My Title!"

# `display(p)` to see the updated plot
display(p)

[joshday]

I think there's still one piece missing in your example, which is Cobweb.save(myplot) which will overwrite the index.html file.

[StefanPofahl]

I have added Cobweb.save(myplot), but it is not clear where myplot is defined.