Add support for setting parameters with a nested Dict

[awadell1]

Currently setting u0 and p requires access to scope that contains @variables / @parameters.

u0 = [
    x => 2.0
    subsys.x => 2.0
]

Could support be added for setting parameters with nested Dicts (Or something similar)?

u0 = Dict(
  :x => 2.0,
  :subsys => Dict(:x => 2.0)
)

A minimal (non-working) example of my use case is below. Basically, I want to define my system in a function (Or compose it programmatically) and then set the parameters and initial state later / in a different scope.

using ModelingToolkit

function decay(;name)
    @parameters t a
    @variables x(t) f(t)
    D = Differential(t)
    ODESystem([
        D(x) ~ -a*x + f
    ];
    name=name)
end

function system()
    # Subsystems
    @named decay1 = decay()
    @named decay2 = decay()

    # Connect Subsystems
    @variables t
    D = Differential(t)
    connections = [
        decay2.f ~ decay1.x,
        D(decay1.f) ~ 0,
    ]
    ODESystem(connections; systems = [decay1, decay2])
end

# x, f, decay1 and decay2 are out of scope here
x0 = Dict(
    :decay1 => Dict(:x => 1.0, f => 0.01),
    :decay2 => Dict(:x => 1.0),
)
p = Dict(
    :decay1 => Dict( :a => 0.1 ),
    :decay2 => Dict( :a => 0.2 ),
)

using OrdinaryDiffEq
prob = ODEProblem(system(), x0, (0.0, 100.0), p)
sol = solve(prob, Tsit5())

I'm happy to work on this, but would need some pointers as to where to start. I'm guessing with varmap_to_vars.

[stonepreston]

did you ever figure out a way to make this happen? I am trying to do the exact same thing. I cant figure out a way to define a parameter map programatically for a predefined system that isnt in the global scope

[awadell1]

I'm currently using this:

function map_parameters(sys, u::Dict, prefix=nothing)
    out = Dict()
    namespace_map = ModelingToolkit.get_var_to_name(sys)
    for (k, v) in u
        k_out = get_symbol(k, prefix)
        if v isa Dict
            out = merge(out, map_parameters(sys,u[k], k))
        elseif haskey(namespace_map, k_out)
            var_out = namespace_map[k_out]
            out[var_out] = v
        end
    end
    out
end

function get_symbol(sym, prefix)
    if prefix === nothing
        return Symbol(sym)
    else
        Symbol(prefix, :₊, sym)
    end
end

Which for the above example would be:

# Convert dict to a format that varmap_to_vars can deal with
sys = system() |> structural_simplify
x0 = map_parameters(sys, x0)
p = map_parameters(sys, p)

# Can now do
using OrdinaryDiffEq
prob = ODEProblem(system(), x0, (0.0, 100.0), p)
sol = solve(prob, Tsit5())

[stonepreston]

can you post that get_symbol function too?

[awadell1]

Ooops, sorry about that. I've updated the code above

[stonepreston]

I cant seem to get it to work. the output dict is empty. Am i missing anything:

using ModelingToolkit

function decay(;name)
    @parameters t a
    @variables x(t) f(t)
    D = Differential(t)
    ODESystem([
        D(x) ~ -a*x + f
    ];
    name=name)
end

function system()
    # Subsystems
    @named decay1 = decay()
    @named decay2 = decay()

    # Connect Subsystems
    @variables t
    D = Differential(t)
    connections = [
        decay2.f ~ decay1.x,
        D(decay1.f) ~ 0,
    ]
    ODESystem(connections; systems = [decay1, decay2])
end

# x, f, decay1 and decay2 are out of scope here

function map_parameters(sys, u::Dict, prefix=nothing)
    out = Dict()
    namespace_map = ModelingToolkit.get_var_to_name(sys)
    for (k, v) in u
        k_out = get_symbol(k, prefix)
        if v isa Dict
            out = merge(out, map_parameters(sys,u[k], k))
        elseif haskey(namespace_map, k_out)
            var_out = namespace_map[k_out]
            out[var_out] = v
        end
    end
    out
end

function get_symbol(sym, prefix)
    if prefix === nothing
        return Symbol(sym)
    else
        Symbol(prefix, :₊, sym)
    end
end

x0 = Dict(
    :decay1 => Dict(:x => 1.0, f => 0.01),
    :decay2 => Dict(:x => 1.0),
)
p = Dict(
    :decay1 => Dict( :a => 0.1 ),
    :decay2 => Dict( :a => 0.2 ),
)

sys = system()
ps = map_parameters(sys, p)

[awadell1]

Turns out it only works if you run structural_simplify on the system first

Updated the sample above

[stonepreston]

yeah it looks like get_var_to_name only returns the state vars if it hasnt been simplified. I wonder if theres some similar function for parameters and not vars. Theres gotta be a way to get that symbol mapping somehow

[stonepreston]

Turns out it only works if you run structural_simplify on the system first

Updated the sample above

bro you are a life saver. Ive been stuck for days trying to figure this out and finally got it working using a method similar to yours to map parameters from JSON to a parameter map to be passed to ODEProblem. Thank you so much. Would still like to find a way to get it working in the non structurally simplified case so if I do ill update this here.