blob: e009f1cce56c6ad99c26c966680d82ad22926c3a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
add_library(app_version INTERFACE)
target_include_directories(app_version
INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
INTERFACE $<INSTALL_INTERFACE:${IDE_HEADER_INSTALL_PATH}/src>)
install(TARGETS app_version EXPORT QtCreator)
add_subdirectory(libs)
add_subdirectory(share)
add_subdirectory(shared)
add_subdirectory(plugins)
add_subdirectory(app)
add_subdirectory(tools)
install(
FILES
${PROJECT_SOURCE_DIR}/HACKING
${PROJECT_SOURCE_DIR}/LICENSES/LICENSE.GPL3-EXCEPT
${PROJECT_SOURCE_DIR}/README.md
DESTINATION ${IDE_DATA_PATH}
COMPONENT Devel EXCLUDE_FROM_ALL
)
install(
DIRECTORY
${PROJECT_SOURCE_DIR}/scripts
DESTINATION ${IDE_DATA_PATH}
COMPONENT Devel EXCLUDE_FROM_ALL
USE_SOURCE_PERMISSIONS
)
install(EXPORT QtCreator
DESTINATION ${IDE_CMAKE_INSTALL_PATH}/QtCreator
COMPONENT Devel EXCLUDE_FROM_ALL
NAMESPACE QtCreator::
FILE QtCreatorTargets.cmake
)
include(CMakePackageConfigHelpers)
set(configure_package_config_file_input_path "${PROJECT_SOURCE_DIR}/cmake/QtCreatorConfig.cmake.in")
set(common_configure_package_config_file_options
NO_SET_AND_CHECK_MACRO
NO_CHECK_REQUIRED_COMPONENTS_MACRO
PATH_VARS
QTCREATOR_RELOCATABLE_INSTALL_PREFIX
)
# Build-tree Config file, used in super build projects that call add_subdirectory(qtcreator).
set(QTCREATOR_RELOCATABLE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}")
configure_package_config_file(
"${configure_package_config_file_input_path}"
"${CMAKE_BINARY_DIR}/cmake/QtCreatorConfig.cmake"
INSTALL_DESTINATION "${CMAKE_BINARY_DIR}/cmake"
INSTALL_PREFIX "${CMAKE_BINARY_DIR}"
${common_configure_package_config_file_options}
)
# Install-tree Config file, used in non-super build projects.
set(QTCREATOR_RELOCATABLE_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
configure_package_config_file(
"${configure_package_config_file_input_path}"
# This is generated into a different directory on purpose, so it doesn't collide with the
# build-tree config file.
"${CMAKE_BINARY_DIR}/cmake/install/QtCreatorConfig.cmake"
INSTALL_DESTINATION "${IDE_CMAKE_INSTALL_PATH}/QtCreator"
${common_configure_package_config_file_options}
)
# Local build export
export(EXPORT QtCreator
NAMESPACE QtCreator::
FILE ${CMAKE_BINARY_DIR}/cmake/QtCreatorTargets.cmake)
file(COPY
${IDE_BRANDING_FILE}
${PROJECT_SOURCE_DIR}/cmake/QtCreatorTranslations.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorDocumentation.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorAPI.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorAPIInternal.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorSbom.cmake
${PROJECT_SOURCE_DIR}/cmake/Config.cmake.in
${PROJECT_SOURCE_DIR}/cmake/QtcSeparateDebugInfo.cmake
${PROJECT_SOURCE_DIR}/cmake/QtcSeparateDebugInfo.Info.plist.in
DESTINATION ${CMAKE_BINARY_DIR}/cmake
)
# Devel package install
install(
FILES
${IDE_BRANDING_FILE}
${PROJECT_SOURCE_DIR}/cmake/QtCreatorTranslations.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorDocumentation.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorAPI.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorAPIInternal.cmake
${PROJECT_SOURCE_DIR}/cmake/QtCreatorSbom.cmake
${PROJECT_SOURCE_DIR}/cmake/Config.cmake.in
${PROJECT_SOURCE_DIR}/cmake/QtcSeparateDebugInfo.cmake
${PROJECT_SOURCE_DIR}/cmake/QtcSeparateDebugInfo.Info.plist.in
${CMAKE_BINARY_DIR}/cmake/install/QtCreatorConfig.cmake
DESTINATION ${IDE_CMAKE_INSTALL_PATH}/QtCreator
COMPONENT Devel EXCLUDE_FROM_ALL
)
|
