Functions > FileDirDisk >

FileWrite

�crit du texte ou des donn�es � la fin d'un fichier pr�c�demment ouvert.

FileWrite ( "filehandle/filename", "text/data" )

Param�tres

filehandle/filename Le handle du fichier retourn� pr�c�demment par FileOpen(). Alternativement, le nom complet du fichier.
text/data Le texte/donn�es � �crire dans le fichier. Le texte est �crit tel quel - pas de @CR ou @LF ajout�. Voir Remarques pour le type de donn�es.

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0 si le fichier n'est pas ouvert en �criture, si le fichier est en lecture seule, ou si le fichier ne peut pas remplacer un autre.

Remarques

Le fichier doit �tre ouvert en �criture, sinon la commande FileWrite() �chouera.

Si un nom de fichier est donn� plut�t qu'un handle de fichier, celui-ci sera ouvert puis ferm� durant l'appel de la fonction. Pour un traitement sur de grands fichiers texte ceci sera beaucoup plus lent que d'utiliser un handle de fichier. Ceci dit, le fichier sera cr�� s'il n'existe pas d�j�.

Note: Ne m�langez pas les handles de fichier et les noms de fichiers, par exemple, n'utilisez pas FileOpen() pour ensuite utiliser le nom du fichier dans cette fonction. Utilisez les handles ou les noms de fichiers dans vos fonctions, mais pas les deux.

Lors de l'�criture d'un texte, AutoIt utilise la norme UTF8 (sans BOM) par d�faut. Pour �crire dans un autre mode, le fichier doit �tre ouvert avec FileOpen() et les flags appropri�s.

Si les donn�es sont de type Variant binaire (et non texte), il sera �crit dans le fichier octet par octet. Une op�ration binaire peut aussi �tre forc�e en utilisant FileOpen() avec le flag binaire.

En relation

Binary, FileFlush, FileGetPos, FileOpen, FileRead, FileReadLine, FileSetPos, FileWriteLine

Exemple

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Cr�e une constante locale avec le chemin du fichier qui sera lu/�crit.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Cr�e un fichier temporaire pour �crire des donn�es.
    If Not FileWrite($sFilePath, "D�marrage de l'exemple FileWrite, ligne 1. " & @CRLF) Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de l'�criture du fichier temporaire.")
        Return False
    EndIf

    ; Ouvre le fichier en �criture (ajoute � la fin du fichier) et stocke le handle dans une variable.
    Local $hFileOpen = FileOpen($sFilePath, $FO_APPEND)
    If $hFileOpen = -1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de la lecture du fichier.")
        Return False
    EndIf

    ; �crit des donn�es dans le fichier � l'aide du handle retourn� par FileOpen.
    FileWrite($hFileOpen, "Ligne 2")
    FileWrite($hFileOpen, "Il s'agit toujours de la ligne 2 car une nouvelle ligne n'a pas �t� ajout�e au dernier appel FileWrite." & @CRLF)
    FileWrite($hFileOpen, "Line 3" & @CRLF)
    FileWrite($hFileOpen, "Line 4")

    ; Ferme le handle retourn� par FileOpen.
    FileClose($hFileOpen)

    ; Affiche le contenu du fichier en passant le chemin du fichier � FILEREAD au lieu du handle retourn�e par FileOpen.
    MsgBox($MB_SYSTEMMODAL, "", "Contents of the file:" & @CRLF & FileRead($sFilePath))

    ; Supprime le fichier temporaire.
    FileDelete($sFilePath)
EndFunc   ;==>Example