Functions > Tray >

TrayCreateItem

Cr�e un contr�le menuitem dans la zone de notification.

TrayCreateItem ( "text" [, menuID = -1 [, menuentry = -1 [, menuradioitem = 0]]] )

Param�tres

text Le texte du contr�le.
menuID [optionnel] Permet de cr�er un sous-menu dans le menu r�f�renc�. Si �gal � -1, il sera ajout� 'derri�re' le dernier item cr�� (par d�faut).
menuentry [optionnel] Vous permet de d�finir le nombre d'entr�es � cr�er. Les entr�es sont num�rot�es � partir de 0. Si �gal � -1, il sera ajout� 'derri�re' la derni�re entr�e cr��e (par d�faut).
menuradioitem [optionnel]
    $TRAY_ITEM_NORMAL (0) (par d�faut) = cr�e un menuitem normal
    $TRAY_ITEM_RADIO (1) = cr�e un 'menuradioitem'.

Les constantes sont d�finies dans "TrayConstants.au3".

Valeur de retour

Succ�s: Retourne l'identifiant (controlID) du nouveau menuitem de la zone de notification.
�chec: Retourne 0.

Remarques

Si le param�tre 'text' est une cha�ne vide ( "" ), alors une ligne de s�paration est cr��e.

Par d�faut, un item de menu coch� (pas un item de menu radio) sera automatiquement d�coch� si vous cliquez dessus!
Pour d�sactiver ce comportement, utilisez Opt("TrayMenuMode", 2).

Les items de menu radio sont automatiquement regroup�s et ces groupes sont s�par�s par une ligne de s�paration ou un item normal, qui n'est pas un item radio.
Par d�faut, un item de menu radio cliqu� sera automatiquement coch� et tous les autres items radio du m�me groupe seront d�coch�s!
Pour d�sactiver ce comportement, utilisez Opt("TrayMenuMode", 8).

En relation

TrayGetMsg, TrayItemDelete, TrayItemSetOnEvent, TrayItemSetState, TrayItemSetText

Exemple

#NoTrayIcon
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; N�cessite les constantes $TRAY_CHECKED et  $TRAY_ICONSTATE_SHOW.

; Les items par d�faut du menu de la zone de notification ne seront pas affich�s et 
; ils ne seront pas coch�s lorsqu'il seront s�lectionn�s. 
; Ce sont les options 1 et 2 de TrayMenuMode.
Opt("TrayMenuMode", 3)

Example()

Func Example()
    ; Cr�e un item de la zone de notification avec le param�tre radio s�lectionn�.
    TrayCreateItem("Radio 1", -1, -1, $TRAY_ITEM_RADIO)
    TrayItemSetState(-1, $TRAY_CHECKED)
    TrayCreateItem("Radio 2", -1, -1, $TRAY_ITEM_RADIO)
    TrayCreateItem("Radio 3", -1, -1, $TRAY_ITEM_RADIO)

    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu dans la zone de notification.

    Local $iASlash, $sPath, $iMsg = TrayGetMsg()
    While $iMsg <> $idExit
        If $iMsg = $idAbout Then 
            ; Affiche une bo�te de message � propos de la version et 
            ; du chemin d'installation de l'ex�cutable AutoIt.

            ; Recherche de droite � gauche l'antislash qui marque la fin du chemin
            $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
            ; Extrait le chemin seul, sans le nom, ni '\'
            $sPath = StringLeft(@AutoItExe, $iASlash - 1)

            MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
                "Version: " & @AutoItVersion & @CRLF & _
                "Chemin d'installation: " & $sPath) 
        EndIf          
        $iMsg = TrayGetMsg()
    WEnd 

EndFunc   ;==>Example