UDF > GDIPlus > Image >

_GDIPlus_DrawImagePoints

Dessine une image � un emplacement sp�cifi�

#include <GDIPlus.au3>
_GDIPlus_DrawImagePoints ( $hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY [, $iCount = 3] )

Param�tres

$hGraphic Handle de l'objet Graphics
$hImage Handle de l'objet Image
$nULX La coordonn�e X du coin sup�rieur gauche de l'image source
$nULY La coordonn�e Y du coin sup�rieur gauche de l'image source
$nURX La coordonn�e X du coin sup�rieur droit de l'image source
$nURY La coordonn�e Y du coin sup�rieur droit de l'image source
$nLLX La coordonn�e X du coin inf�rieur gauche de l'image source
$nLLY La coordonn�e Y du coin inf�rieur gauche de l'image source
$iCount [optionnel] Le nombre de points (x, y) de la structure.

Valeur de retour

Succ�s: Retourne True
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ( GDIP_ERR*).

Remarque

La valeur du param�tre $iCount doit �tre �gal � 3 pour sp�cifier les coordonn�es du coin sup�rieur gauche, coin sup�rieur droit, et le coin inf�rieur gauche du parall�logramme.
La coordonn�e du coin en bas � droite, la largeur et la hauteur de l'image, sont calcul�s � l'aide des trois coordonn�es donn�es.
L'image est redimensionn�e � la taille du parall�logramme.

Voir aussi

Consultez GdipDrawImagePoints dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic

    ; Initialise la biblioth�que GDI+
    _GDIPlus_Startup()

    ; Capture l'�cran complet
    $hBitmap1 = _ScreenCapture_Capture("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)

    ; Capture une r�gion d'�cran
    $hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
    $hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)

    ; Dessine une image dans une autre
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)

    _GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)

    ; Dessine un cadre autour de l'image ins�r�e
    _GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)

    ; Enregistre l'image r�sultante
    _GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Nettoie les ressources
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_ImageDispose($hImage2)
    _WinAPI_DeleteObject($hBitmap1)
    _WinAPI_DeleteObject($hBitmap2)

    ; Arr�te la biblioth�que GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image.jpg")
EndFunc   ;==>Example