UDF > GDIPlus > GraphicsCoders >

_GDIPlus_ParamInit

Alloue une liste vide de param�tres d'un encodeur

#include <GDIPlus.au3>
_GDIPlus_ParamInit ( $iCount )

Param�tre

$iCount Le nombre total de $tagGDIPENCODERPARAM que la liste peut contenir

Valeur de retour

Succ�s: Retourne une structure $tagGDIPENCODERPARAMS.
�chec: D�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Afin de passer des param�tres � l'une des fonctions de l'encodeur, vous devez utiliser une liste de param�tres de l'encodeur.
Cette fonction est utilis�e pour attribuer une liste de param�tres � l'encodeur qui peut ensuite �tre transmis � _GDIPlus_ParamAdd() pour les ajouter aux param�tres actuels.

En relation

$tagGDIPENCODERPARAM, $tagGDIPENCODERPARAMS, _GDIPlus_ParamAdd

Exemple

#include <GDIPlus.au3>
#include <ScreenCapture.au3>

Example()

Func Example()
    Local $hImage, $sCLSID, $tData, $tParams

    ; Capture l'�cran
    _ScreenCapture_Capture(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Initialise la biblioth�que GDI+
    _GDIPlus_Startup()

    ; Charge l'image
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Obtient le CLSID de l'encodeur JPEG
    $sCLSID = _GDIPlus_EncodersGetCLSID("JPG")

    ; Met en place des param�tres pour la rotation de 90 degr�s
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; Enregistre l'image pivot�e
    _GDIPlus_ImageSaveToFileEx($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; Arr�te biblioth�que GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image2.jpg")
EndFunc   ;==>Example