UDF > SQLite >

_SQLite_FetchNames

Retourne dans une variable de sortie les noms des colonnes relative � une requ�te _SQLite_Query()

#include <SQLite.au3>
_SQLite_FetchNames ( $hQuery, ByRef $aNames )

Param�tres

$hQuery Handle Query retourn� par SQLite_Query()
$aNames Tableau � une dimension contenant les noms des colonnes

Valeur de retour

Succ�s: Retourne $SQLITE_OK.
�chec: Retourne une valeur qui peut �tre compar�e aux constantes $SQLITE_*.
@error: -1 - SQLite a signal� une erreur (Examinez la valeur de retour)
 1 - Erreur dans l'appel de l'API SQLite 'sqlite3_data_count'
 2 - Erreur dans l'appel de l'API SQLite 'sqlite3_column_name16'
 3 - Appel emp�ch� par SafeMode

En relation

_SQLite_Query

Exemple

#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $hQuery, $aRow, $aNames
_SQLite_Startup()
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; Ouvre une base de donn�es :memory:
_SQLite_Exec(-1, "CREATE TABLE aTest (A,B,C); ")
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('c','2','World'); ")
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('b','3',' '); ")
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('a','1','Hello'); ")
_SQLite_Query(-1, "SELECT ROWID,* FROM aTest ORDER BY a; ", $hQuery)
_SQLite_FetchNames($hQuery, $aNames) ; Lit les noms de Colonnes
ConsoleWrite(StringFormat(" %-10s  %-10s  %-10s  %-10s ", $aNames[0], $aNames[1], $aNames[2], $aNames[3]) & @CRLF)
While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK
    ConsoleWrite(StringFormat(" %-10s  %-10s  %-10s  %-10s ", $aRow[0], $aRow[1], $aRow[2], $aRow[3]) & @CRLF)
WEnd
_SQLite_Exec(-1, "DROP TABLE aTest; ")
_SQLite_Close()
_SQLite_Shutdown()

; R�sultat:
; rowid       A           B           C
; 3           a           1           Hello
; 2           b           3
; 1           c           2           World