UDF > Word >

_Word_DocFindReplace

Ex�cute la recherche sp�cifi� et l'op�ration de remplacement

#include <Word.au3>
_Word_DocFindReplace ( $oDoc [, $sFindText = "" [, $sReplaceWith = "" [, $iReplace = $WdReplaceAll [, $vSearchRange = 0 [, $bMatchCase = False [, $bMatchWholeWord = False [, $bMatchWildcards = False [, $bMatchSoundsLike = False [, $bMatchAllWordForms = False [, $bForward = True [, $iWrap = $WdFindContinue [, $bFormat = False]]]]]]]]]]]] )

Param�tres

$oDoc Document Word objet
$sFindText [optionnel] Le texte � rechercher. Utilisez une cha�ne vide ("") pour rechercher seulement un format.
Vous pouvez rechercher des caract�res sp�ciaux en sp�cifiant les codes de caract�res appropri�s.
Par exemple,"^p" correspond � une marque de paragraphe et "^t" correspond � un caract�re de tabulation (par default = "")
$sReplaceWith [optionnel] Le texte de remplacement. Pour supprimer le texte trouv� utilisez une cha�ne vide ("").
Vous pouvez sp�cifier des caract�res sp�ciaux et des crit�res de recherche avanc�e comme vous pouvez le faire pour l'argument Find (default = "")
$iReplace [optionnel] Combien de remplacements doivent �tre faits: un, tous ou aucun.
Peut �tre toute constante de WdReplace (par d�faut $wdReplaceAll)
$vSearchRange [optionnel] Sp�cifie la s�lection ou la plage dans laquelle rechercher. Peut �tre:
    -1 - Indique la s�lection actuelle
     0 - Indique le document entier (par d�faut)
Tout objet plage de Word.
$bMatchCase [optionnel] Si True, la recherche est sensible � la casse (par d�faut = False)
$bMatchWholeWord [optionnel] Si True, seuls des mots entiers sont recherch�s (par d�faut = False)
$bMatchWildcards [optionnel] Si True, le texte � rechercher contient des op�rateurs sp�ciaux de recherche (par d�faut = False)
$bMatchSoundsLike [optionnel] Si True, recherche des mots phon�tiquement similaire au texte de la recherche (par d�faut = False)
$bMatchAllWordForms [optionnel] Si True, recherche toutes les formes du texte � rechercher
(par exemple, "sit" retiendra "sitting" et "sat") (par d�faut = False)
$bForward [optionnel] True pour rechercher vers l'avant (vers la fin du document) (valeur par d�faut = True)
$iWrap [optionnel] True, boucle quand le bas ou le haut du document, de la s�lection ou de la plage est atteint.
Peut �tre l'une des constantes de WdFindWrap (par d�faut = $wdFindContinue)
$bFormat [optionnel] True, pour que l'op�ration de recherche concerne un format en plus ou � la place du texte � rechercher (par d�faut = False)

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0 et d�finit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - $vSearchRange n'est pas un objet
3 - Une erreur est apparue quand l'op�ration de remplacement a �t� effectu�e. @extended contient le code d'erreur COM.

En relation

_Word_DocFind

Exemple

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Change le document test en rempla�ant du texte.
;
_Word_DocFindReplace($oDoc, "test document", "test document with replaced text")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error replacing text in the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", "Text successfully replaced.")

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Remplace le caract�re de contr�le paragraph par paragraph + text + paragraph.
; Change seulement la premi�re occurrence.
;
_Word_DocFindReplace($oDoc, "^p", "^pInserted Line^p", $wdReplaceOne)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", _
        "Error replacing text in the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Example", "Paragraph control character successfully replaced.")