UDF > Word >

_Word_DocLinkAdd

Ajoute un lien hypertexte dans le document

#include <Word.au3>
_Word_DocLinkAdd ( $oDoc [, $oAnchor = Default [, $sAddress = Default [, $sSubAddress = Default [, $sScreenTip = Default [, $sTextToDisplay = Default [, $sTarget = Default]]]]]] )

Param�tres

$oDoc Objet document Word
$oAnchor [optionnel] Objet Range pour le texte ou le graphique qui doit �tre transform� en un lien hypertexte
(par d�faut = Utilise le document entier comme plage)
$sAddress [optionnel] L'adresse du lien sp�cifi�.
L'adresse peut �tre une adresse e-mail, une adresse Internet ou un nom de fichier (par d�faut = lien vers le document sp�cifi�)
$sSubAddress [optionnel] Le nom d'un emplacement dans le fichier de destination, comme un signet, une plage nomm�e
ou un num�ro de diapositive (par d�faut = Aucun)
$sScreenTip [optionnel] Le texte qui appara�t comme une bulle lorsque le pointeur de la souris est positionn� sur le
lien hypertexte donn� (par d�faut = Utilise la valeur de $sAddress )
$sTextToDisplay [optionnel] Le texte d'affichage du lien hypertexte sp�cifi�.
La valeur de cet argument remplace le texte ou le graphique sp�cifi� par $oAnchor (par d�faut = Utilise la valeur de $sAddress )
$sTarget [optionnel] Le nom du cadre ou de la fen�tre dans lequel vous souhaitez charger le lien hypertexte sp�cifi�

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0 et d�finit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - Une erreur s'est produite lors de l'ajout du lien. @extended contient le code d'erreur COM
3 - $oAnchor n'est pas 0 mais n'est pas un objet Range

En relation

_Word_DocLinkGet

Exemple

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre test.doc en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Faire du quatri�me mot du document un lien vers la page d'accueil de AutoIt
;
Local $oRange = _Word_DocRangeSet($oDoc, -1, $wdWord, 3, $wdWord, 1)
_Word_DocLinkAdd($oDoc, $oRange, "http://www.autoitscript.com")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error adding a link to the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", "Word 4 of the document is now a link to the AutoIt homepage.")

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre test.doc en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ajoute un lien � la fin du document et d�finit les param�tres
; ScreenTip and TextToDisplay
;
Local $oRange = _Word_DocRangeSet($oDoc, -2) ; Va � la fin du document
$oRange.Text = " " ; Ajoute un espace � la fin du document
$oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocLinkAdd($oDoc, $oRange, "http://www.autoitscript.com", Default, "AutoIt homepage", _
        "Hyperlink 3 - Another link to the AutoIt homepage")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", _
        "Error adding a link to the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Example", "Hyperlink added to the end of the document.")