UDF > Word >

_Word_DocPictureAdd

Ajoute une image dans le document

#include <Word.au3>
_Word_DocPictureAdd ( $oDoc, $sFilePath [, $bLinkToFile = False [, $bSaveWithDocument = False [, $oRange = 0]]] )

Param�tres

$oDoc Objet document Word
$sFilePath Le chemin et le nom du fichier de l'image
$bLinkToFile [optionnel] Sp�cifie s'il faut relier l'image au fichier � partir duquel elle a �t� cr��e.
    True - Relie l'image au fichier � partir duquel elle a �t� cr��e
    False - Copie l'image pour qu'elle soit ind�pendante du fichier (par d�faut)
$bSaveWithDocument [optionnel] Sp�cifie si vous souhaitez enregistrer l'image reli�e au document.
    True - Enregistrer l'image li�e avec le document
    False - N'enregistre pas l'image li�e avec le document (par d�faut)
$oRange [optionnel] L'emplacement o� l'image sera plac�e dans le texte.
Peut �tre 0 (la photo est automatiquement positionn�e) ou tout autre objet plage (par d�faut = 0)

Valeur de retour

Succ�s: Retourne une variable pointant sur l'objet Forme
�chec: Retourne 0 et d�finit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - L'image sp�cifi�e n'existe pas
3 - Une erreur s'est produite lors de l'ajout de l'image sp�cifi�e. @extended contient le code d'erreur COM
4 - $oRange n'est pas 0 mais n'est pas un objet plage

Exemples

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document de test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ins�re une image apr�s le quatri�me mot du document
;
; D�finit la plage comme marqueur d'insertion apr�s le 4�me mot
Local $oRange = _Word_DocRangeSet($oDoc, -1, Default, 4, Default, 4)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added after word 4 in the document.")

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ajoute une image � la fin du document
;
; D�finit la plage comme marqueur d'insertion � la fin du document
Local $oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added at the end of the document.")