UDF > Word >

_Word_DocSaveAs

Enregistre le document Word sp�cifi� avec un nom ou un format nouveau

#include <Word.au3>
_Word_DocSaveAs ( $oDoc [, $sFileName = Default [, $iFileFormat = $WdFormatDocument [, $bReadOnlyRecommended = False [, $bAddToRecentFiles = True [, $sPassword = "" [, $sWritePassword = ""]]]]]] )

Param�tres

$oDoc Objet document Word
$sFileName [optionnel] Le nom complet du document (par d�faut = le dossier actuel et le nom du fichier en cours).
Si le document n'a jamais �t� enregistr�, un nom par d�faut est utilis� (par exemple, Doc1.doc)
$iFileFormat [optionnel] Le format dans lequel le document doit �tre enregistr�.
Peut prendre toute valeur de wdSaveFormat (par d�faut = $wdFormatDocument)
$bReadOnlyRecommended [optionnel] True pour que Word sugg�re le statut lecture seule chaque fois que le document est ouvert (par d�faut = False)
$bAddToRecentFiles [optionnel] True pour ajouter le document � la liste des fichiers r�cemment utilis�s (par d�faut = True)
$sPassword [optionnel] Une cha�ne mot de passe pour ouvrir le document (par d�faut = "")
$sWritePassword [optionnel] Une cha�ne mot de passe pour enregistrer les modifications au document (par d�faut = "")

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0 et d�finit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - Une erreur s'est produite lors de l'enregistrement du document sp�cifi�. @extended contient le code d'erreur COM

Remarque

Si un document avec le nom de fichier sp�cifi� existe d�j�, le document sera �cras� sans que l'utilisateur soit pr�alablement averti.

En relation

_Word_DocSave

Exemple

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Copie \Extras\Test.doc vers @TempDir
If FileCopy(@ScriptDir & "\Extras\Test.doc", @TempDir & "\_Word_Test.doc", $FC_OVERWRITE) = 0 Then Exit MsgBox($MB_SYSTEMMODAL, _
        "Word UDF: _Word_DocSaveAs Example", "Couldn't copy '.\Extras\Test.doc' as '_Word_Test.doc' to the @TempDir directory.")
; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document test
Local $oDoc = _Word_DocOpen($oWord, @TempDir & "\_Word_Test.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error opening '_Word_Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Enregistre le document sous le nom _Word_Test2.doc
;
; Insert text at the beginning
Local $oRange = _Word_DocRangeSet($oDoc, -1)
$oRange.Text = "Bold text at the beginning. "
$oRange.Bold = True
; Enregistre le document
_Word_DocSaveAs($oDoc, @TempDir & "\_Word_Test2.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error saving the Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", "Document successfully saved as '" & _
        @TempDir & "\_Word_Test2.doc'.")