UDF > Word >

_Word_Quit

Ferme tous les documents, l'application Word et supprime les r�f�rences d'objet vers elle

#include <Word.au3>
_Word_Quit ( $oAppl [, $iSaveChanges = $WdDoNotSaveChanges [, $iOriginalFormat = $WdWordDocument [, $bForceClose = False]]] )

Param�tres

$oAppl Objet Word retourn� par un pr�c�dent appel � _Word_Create()
$iSaveChanges [optionnel] Sp�cifie si les documents modifi�s doivent �tre sauvegard�s avant la fermeture.
Peut prendre toute valeur de l'�num�ration WdSaveOptions (par d�faut = $wdDoNotSaveChanges)
$iOriginalFormat [optionnel] Sp�cifie la fa�on dont Word enregistre les documents dont le format d'origine n'�tait pas le format de document Word.
Peut prendre toute valeur de l'�num�ration WdOriginalFormat (par d�faut = $WdWordDocument)
$bForceClose [optionnel] Si True, l'application Word est ferm�e m�me pendant l'ex�cution de _Word_Create() (par d�faut = False)

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0 et d�finit @error <> 0.
@error: 1 - $oAppl n'est pas un objet
2 - Erreur retourn�e par la m�thode Application.Quit. @extended contient le code d'erreur COM

Remarque

Si Word n'est pas en cours d'ex�cution lors de l'appel de _Word_Create() alors _Word_Quit() ferme tous les documents de l'instance
sp�cifi�e (m�me celles ouvertes manuellement par l'utilisateur apr�s _Word_Create() ) ainsi que l'application Word.
Si Word est en cours d'ex�cution, vous devez d�finir $bForceClose � True pour faire la m�me chose.

En relation

_Word_Create

Exemple

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Cr�e un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocQuit Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $bWordClose = @extended
; Ouvre le document test en lecture seule
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocQuit Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Si Word �tait en cours d'ex�cution quand ce script a d�marr�, seule les r�f�rences � cet
; objet seront d�truites.
; Si Word a �t� d�marr� par cet exemple tous les documents ainsi que Word seront ferm�s.
;
Local $iResult
If $bWordClose Then
    $iResult = MsgBox(BitOR($MB_OKCANCEL, $MB_SYSTEMMODAL), "Word UDF: _Word_Quit Example", _
            "If you click OK ALL unsaved changes in ALL open documents of this Word instance will be lost and the instance will be closed.")
Else
    $iResult = MsgBox(BitOR($MB_OKCANCEL, $MB_SYSTEMMODAL), "Word UDF: _Word_Quit Example", _
            "Word was already running when function _Word_Create was called. Hence only the reference to the object will be removed.")
EndIf
If $iResult = 2 Then Exit
_Word_Quit($oWord)
If @error Then MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Quit Example", _
        "Error closing the Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)