Functions > GUI > GUICtrlCreate >

GUICtrlCreateCheckbox

Cr�e un contr�le Checkbox pour une GUI.

GUICtrlCreateCheckbox ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Param�tres

text Texte du contr�le Checkbox
left Coordonn�e X du coin sup�rieur gauche du contr�le. Si �gale � -1, alors X sera calcul�e en fonction de GUICoordMode.
top Coordonn�e Y du coin sup�rieur gauche du contr�le. Si �gale � -1, alors Y sera calcul�e en fonction de GUICoordMode.
width [optionnel] Largeur du contr�le (Ajuste automatiquement le texte par d�faut dans la largeur).
height [optionnel] Hauteur du contr�le (Ajuste automatiquement le texte par d�faut dans la largeur).
style [optionnel] D�finit le style du contr�le. Consultez l'Annexe des styles de contr�le de GUI.
    Par d�faut (-1) : $BS_AUTOCHECKBOX.
    Styles forc�s : $WS_TABSTOP, et $BS_AUTOCHECKBOX si aucun styles chekkbox n'est d�fini.
exStyle [optionnel] D�finit le style �tendu du contr�le. Consultez la Table des styles �tendus.

Valeur de retour

Succ�s: Retourne l'ID du nouveau contr�le.
�chec: Retourne 0.

Remarques

Pour obtenir la valeur du contr�le, consultez GUICtrlRead.
Pour d�finir ou modifier des informations dans le contr�le, consultez GUICtrlUpdate....

Un contr�le de cases � cocher permet d'afficher une ic�ne ou une image en utilisant le style $BS_ICON ou $BS_BITMAP. Utilisez GUICtrlSetImage pour sp�cifier l'image � utiliser.

Pour combiner les styles avec les styles par d�faut, utilisez BitOR/a>($GUI_SS_DEFAULT_CHECKBOX, newstyle,...).

Pour utiliser les valeurs sp�cifi�es ci-dessus, vous devez ajouter #include <ButtonConstants.au3> dans votre script.

Le redimensionnement par d�faut est $GUI_DOCKHEIGHT.

En relation

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Exemple

 
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Cr�e une GUI avec diff�rents contr�les.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Cr�e un contr�le Checkbox.
    Local $idCheckbox = GUICtrlCreateCheckbox("Standard Checkbox", 10, 10, 185, 25)
    Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg()
    While ($idMsg <> $GUI_EVENT_CLOSE) And ($idMsg <> $idClose) 
        If $idMsg = $idCheckbox Then
            If _IsChecked($idCheckbox) Then
                MsgBox($MB_SYSTEMMODAL, "", "La checkbox est coch�e.", 0, $hGUI)
            Else
                MsgBox($MB_SYSTEMMODAL, "", "La checkbox n'est pas coch�e.", 0, $hGUI)
            EndIf
        EndIf
        $idMsg = GUIGetMsg()
    WEnd

    ; Supprime l'interface graphique pr�c�dente et tous ses contr�les.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _IsChecked($idControlID)
    Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked