Functions > GUI > GUICtrlCreate >

GUICtrlCreateTabItem

Cr�e un �l�ment pour un contr�le Tab.

GUICtrlCreateTabItem ( "text" )

Param�tre

text Le texte du contr�le.

Valeur de retour

Succ�s: Retourne l'ID du nouvel �l�ment.
�chec: Retourne 0.

Remarques

Pour s�lectionner un TabItem sp�cifique � afficher lorsque la GUI s'ouvre, utilisez GUICtrlSetState(-1, $GUI_SHOW), comme illustr� dans l'exemple.

Il est important de fermer la structure Tab en cr�ant un contr�le TabItem final avec un texte null - GUICtrlCreateTabItem("").

Les contr�les pour un TabItem sp�cifique devraient �tre cr��s apr�s le TabItem et avant la cr�ation d'une nouveau TabItem ou la fermeture de la structure du Tab. Pour cr�er un nouveau contr�le dans un TabItem existant, utilisez GUISwitch($hWin, $tabitem) pour choisir le TabItem correct et ensuite cr�er le nouveau contr�le. N'oubliez pas de fermer la structure TabItem avec GUICtrlCreateTabItem("").

Le contr�le TabItem ne peut �tre color� (trop de code ...).

GUICtrlRead() retournera l'index du TabItem cliqu�, ou le controlID lorsque le mode avanc� est utilis�.

Pour d�finir ou modifier des informations dans le contr�le, consultez les fonctions GUICtrlUpdate...().

En relation

GUICtrlCreateTab, GUICtrlRead, GUICtrlSetState, GUIEventOptions (Option), GUIGetMsg, GUISwitch

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("My GUI Tab", 250, 150); Cr�e une GUI centr�e

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    Local $idTab = GUICtrlCreateTab(10, 10, 200, 100)
    GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    GUICtrlCreateInput("default", 80, 50, 70, 20)

    GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon");Jon d�faut
    GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW); s'affichera en premier
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem(""); fin de la d�finition de TabItem

    GUICtrlCreateLabel("Click on tab and see the title", 20, 130, 250, 20)

    GUISetState(@SW_SHOW)

    Local $idMsg = GUIGetMsg()
    ; Boucle jusqu'� ce que l'utilisateur quitte.
    While $idMsg <> $GUI_EVENT_CLOSE
        If $idMsg = $idTab Then
            ; Affiche l'onglet cliqu�
            WinSetTitle("My GUI Tab", "", "My GUI Tab" & GUICtrlRead($idTab))
        EndIf
        $idMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example