Functions > GUI > GUICtrlUpdate >

GUICtrlSetBkColor

D�finit la couleur de fond d'un contr�le.

GUICtrlSetBkColor ( controlID, backgroundcolor )

Param�tres

controlID L'identifiant du contr�le tel que retourn� par une fonction GUICtrlCreate...(), ou -1 pour d�signer le dernier contr�le cr��.
backgroundcolor La couleur RVB � utiliser.

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0.

Remarques

Seuls les contr�les Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress, Slider et Combo peuvent actuellement �tre color�s.

Les contr�les Progress ne peuvent pas �tre peints si le "style Windows XP" est utilis�.
Les contr�les Checkbox, Radio, Groupe Progr�s, Combo ne peuvent pas �tre peints si le "style de Windows XP/Vista" est utilis�.

Les contr�les Button sont toujours peints en "style Windows Classique". Ils ne peuvent pas avoir le style $BS_ICON.

Le flag sp�cial $GUI_BKCOLOR_TRANSPARENT peut �tre utilis� avec es contr�les Label, Group, Radio, Checkbox pour leur donner un fond transparent.

Le flag sp�cial $GUI_BKCOLOR_LV_ALTERNATE peut �tre utilis� avec le contr�le ListView pour lui donner un fond diff�rent suivant les lignes des ListviewItems.
Les lignes impaires obtiendront la couleur d�finie par GUICtrlSetBkColor() du contr�le ListView.
Les lignes paires auront la couleur d�finie par GUICtrlSetBkColor() du contr�le ListViewItem.

En relation

GUICtrlCreate..., GUICtrlSetColor, GUICtrlSetDefBkColor

Exemple

Exemple 1

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Cr�e une GUI avec diff�rents contr�les.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Cr�e un contr�le Label.
    Local $idLabel = GUICtrlCreateLabel("A string of text", 10, 10, 185, 17)
    Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    ; D�finit la couleur de fond du contr�le Label.
    GUICtrlSetBkColor($idLabel, $COLOR_RED)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Local $idMsg
    Do
        $idMsg = GUIGetMsg()
    Until $idMsg = $GUI_EVENT_CLOSE Or $idMsg = $idClose

    ; Supprime la GUI pr�c�dente et tous ses contr�les.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Exemple 2

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>

Example()

Func Example()
    ; Cr�e une GUI avec une listview.
    Local $hGUI = GUICreate("Colored ListView Items", 250, 170, 100, 200, -1)
    Local $idListview = GUICtrlCreateListView("col1|col2|col3", 10, 10, 230, 150)

    ; Alterne entre la couleur du fond de la listview et la couleur du fond des items de la listview.
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_LV_ALTERNATE)

    ; D�finit la couleur du fond de la listview.
    ; Les items pairs de la listview seront de la couleur du fond de la listview,
    ; Les impairs avec la couleur du fond des items de la listview.
    GUICtrlSetBkColor(-1, $COLOR_AQUA)

    ; Cr�e des items de la listview et d�finit la couleur de fond pour chacun d'eux.
    GUICtrlCreateListViewItem("item1|col12|col13", $idListview)

    ; La ligne suivante pourrait �tre supprim�e lorsque la couleur de fond est tir�e de la listview.
    GUICtrlSetBkColor(-1, $COLOR_GREEN)
    GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
    GUICtrlSetBkColor(-1, $COLOR_GREEN)
    GUICtrlCreateListViewItem("item3|col32|col33", $idListview)

    ; ; La ligne suivante pourrait �tre supprim�e lorsque la couleur de fond est tir�e de la listview.
    GUICtrlSetBkColor(-1, $COLOR_GREEN)

    ; Change la couleur d'un seul item de la listview.
    GUICtrlCreateListViewItem("Now|change|color", $idListview)
    GUICtrlSetBkColor(-1, $COLOR_LIME)
    GUICtrlCreateListViewItem("item5|col52|col53", $idListview)

    ; La ligne suivante pourrait �tre supprim�e lorsque la couleur de fond est tir�e de la listview.
    GUICtrlSetBkColor(-1, $COLOR_GREEN)
    GUICtrlCreateListViewItem("item6|col62|col63", $idListview)
    GUICtrlSetBkColor(-1, $COLOR_GREEN)
    GUISetState(@SW_SHOW, $hGUI)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
 
    ; Supprime la GUI pr�c�dente et tous ses contr�les
    GUIDelete($hGUI)
EndFunc   ;==>Example