Functions > GUI > GUICtrlUpdate >

GUICtrlSetResizing

D�finit la m�thode de redimensionnement utilis�e par un contr�le.

GUICtrlSetResizing ( controlID, resizing )

Param�tres

controlID L'identifiant du contr�le tel que retourn� par une fonction GUICtrlCreate...(), ou -1 pour d�signer le dernier contr�le cr��.
resizing Voir la Tableau des valeurs d'Ancrage ci-dessous pour les valeurs qui peuvent �tre utilis�es (additionner plusieurs valeurs si n�cessaire).

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0.

Remarques

Quand une fen�tre GUI est redimensionn�e, ses contr�les r�agissent - la fa�on dont ils r�agissent est d�termin�e par cette fonction. Pour �tre en mesure de redimensionner une fen�tre GUI, elle doit avoir �t� cr��e avec les styles $WS_SIZEBOX et $WS_SYSMENU. Consultez GUICreate().

    Tableau des valeurs d'Ancrage

Redimensionnement Valeur Aucun d�placement de
$GUI_DOCKAUTO 1 Redimensionne et repositionne en accord avec la nouvelle taille de la fen�tre
$GUI_DOCKLEFT 2 Cot� gauche
$GUI_DOCKRIGHT 4 Cot� droit
$GUI_DOCKHCENTER 8 La position ne se d�placera pas par rapport � l'axe central horizontal
$GUI_DOCKTOP 32 Cot� sup�rieur
$GUI_DOCKBOTTOM 64 Cot� inf�rieur
$GUI_DOCKVCENTER 128 La position ne se d�placera par rapport � l'axe central vertical
$GUI_DOCKWIDTH 256 La largeur ne changera pas
$GUI_DOCKHEIGHT 512 La hauteur ne changera pas
Redimensionnement compos�
$GUI_DOCKSIZE 768 (256+512) La taille ne changera pas
$GUI_DOCKMENUBAR 544 (512+32) Donc le contr�le restera en haut de la fen�tre sans changement de hauteur
$GUI_DOCKSTATEBAR 576 (512+64) Donc le contr�le restera en bas de la fen�tre sans changement de hauteur
$GUI_DOCKALL 802 (2+32+256+512) Donc le contr�le ne se d�placera pas pendant le redimensionnement
$GUI_DOCKBORDERS 102 (2+4+32+64) Donc le contr�le va cro�tre comme la fen�tre

La valeur par d�faut de redimensionnement pour un contr�le donn� d�pend du contr�le, voir la documentation sur le contr�le.

L'�v�nement de redimensionnement automatique peut �tre d�sactiv� si GUIEventOptions (Option) est mis � 1.

En relation

GUICtrlCreate..., GUIEventOptions (Option), GUIResizeMode (Option)

Exemple

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Opt("GUICoordMode", 2)
    GUICreate("My InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; commence la d�finition

    GUISetFont(8, -1, "Arial")

    GUICtrlCreateLabel("Prompt", 8, 7) ; ajoute des informations rapides
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

    Local $idEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; ajoute une zone de saisie
    GUICtrlSetState($idEdit, $GUI_FOCUS)
    GUICtrlSetResizing($idEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

    Local $idOK = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; ajoute un bouton qui fermera la GUI
    GUICtrlSetResizing($idOK, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    Local $idCancel = GUICtrlCreateButton("Annuler", 25, -1) ; ajoute le bouton qui fermera la GUI
    GUICtrlSetResizing($idCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    GUISetState(@SW_SHOW) ;pour afficher l'interface graphique

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example