Functions > GUI >

GUIGetCursorInfo

Obtient la position du curseur de la souris par rapport � la GUI.

GUIGetCursorInfo ( [winhandle] )

Param�tre

winhandle

[optionnel] Le handle de la fen�tre � utiliser. En cas d'omission, la fen�tre 'courante' sera utilis�e.

Valeur de retour

Succ�s:	Retourne un tableau de cinq �l�ments qui contient des informations sur le curseur de la souris : $aArray[0] = coord X (horizontal) $aArray[1] = coord Y (vertical) $aArray[2] = bouton gauche press� (1=press�, 0=non press�) $aArray[3] = bouton droit press� (1=press�, 0=non press�) $aArray[4] = ID du contr�le que le curseur de la souris survole (ou 0 si aucun)
�chec:	D�finit @error <> 0.

Remarques

Les coordonn�es donn�es sont relatives � la fen�tre GUI (connu sous le nom de coordonn�es clientes).

Si le param�tre 'winhandle' est utilis�, alors la fen�tre sp�cifi�e devient la nouvelle fen�tre 'courante'.

La position du curseur de la souris n'est couronn�e de succ�s que sur une fen�tre cr��e par un GUICreate(). Quand il n'y a pas de handle de fen�tre, ce sera un succ�s seulement si la fen�tre GUI est active.

Le controlID d'un ListViewItem ou d'un TreeViewItem ne sera jamais retourn�, seul le controlID du parent ListView ou TreeView le sera.

En relation

GUICreate, GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>

Global $g_idX = 0, $g_idY = 0

Example()

Func Example()
    HotKeySet("{ESC}", "GetPos")

    GUICreate("Pressez Esc pour obtenir la position", 400, 400)
    $g_idX = GUICtrlCreateLabel("0", 10, 10, 50)
    $g_idY = GUICtrlCreateLabel("0", 10, 30, 50)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example

Func GetPos()
    Local $a = GUIGetCursorInfo()
    GUICtrlSetData($g_idX, $a[0])
    GUICtrlSetData($g_idY, $a[1])
EndFunc   ;==>GetPos