Functions > GUI > GUISetParameters >

GUISetOnEvent

D�finit l'appel d'une fonction utilisateur lorsqu'un bouton syst�me est cliqu�.

GUISetOnEvent ( specialID, "function" [, winhandle] )

Param�tres

specialID Consultez le Tableau des IDs Sp�ciaux ci-dessous.
function Le nom de la fonction utilisateur � appeler.
winhandle [optionnel] Handle Windows retourn� par GUICreate() (par d�faut, la fen�tre pr�c�demment utilis�e).

Valeur de retour

Succ�s: Retourne 1.
�chec: Retourne 0.

Remarques

Les fonctions OnEvent ne sont appel�es que si l'option GUIOnEventMode est � 1 - Dans ce mode, GUIGetMsg() n'est pas utilis�e du tout.

Vous ne pouvez pas appeler une fonction avec des param�tres.

Si l'option GUIEventOptions est � 1, les boutons system 'minimise', 'restaure' et 'maximise' n'auront aucun effet sur la fen�tre, juste une simple notification.

Si le param�tre "function" est une cha�ne vide "", la fonction utilisateur pr�c�dente est d�sactiv�e.
    Table des IDs Sp�ciaux

Identifiant Sp�cial Commentaires
$GUI_EVENT_CLOSE La bo�te de dialogue est en train d'�tre ferm�e (par bouton d�fini ou par menu syst�me).
$GUI_EVENT_MINIMIZE La bo�te de dialogue est minimis�e avec le bouton de la barre de titre.
$GUI_EVENT_RESTORE La bo�te de dialogue est restaur�e par un clic sur l'ic�ne de la barre de t�che.
$GUI_EVENT_MAXIMIZE La bo�te de dialogue est maximis�e avec le bouton de la barre de titre.
$GUI_EVENT_MOUSEMOVE Le curseur de la souris a �t� d�plac�.
$GUI_EVENT_PRIMARYDOWN le bouton principal de la souris a �t� press�.
$GUI_EVENT_PRIMARYUP le bouton principal de la souris a �t� rel�ch�.
$GUI_EVENT_SECONDARYDOWN le bouton secondaire de la souris a �t� press�.
$GUI_EVENT_SECONDARYUP le bouton secondaire de la souris a �t� rel�ch�.
$GUI_EVENT_RESIZED La bo�te de dialogue a �t� redimensionn�e.
$GUI_EVENT_DROPPED Fin d'une action Drag&Drop. Les macros @GUI_DragId, @GUI_DragFile et @GUI_DropId seront utilis�s pour obtenir l'ID/fichier du contr�le impliqu�.

En relation

GUICtrlSetOnEvent, GUIEventOptions (Option), GUIOnEventMode (Option)

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $bEndScript = False
Example()

Func Example()
    Opt("GUICoordMode", 2)
    Opt("GUIResizeMode", 1)
    Opt("GUIOnEventMode", 1)

    GUICreate("Parent1")
    GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
    GUISetOnEvent($GUI_EVENT_MINIMIZE, "SpecialEvents")
    GUISetOnEvent($GUI_EVENT_RESTORE, "SpecialEvents")

    GUICtrlCreateButton("OK", 10, 30, 50)
    GUICtrlSetOnEvent(-1, "OKPressed")

    GUICtrlCreateButton("Cancel", 0, -1)
    GUICtrlSetOnEvent(-1, "CancelPressed")

    GUISetState(@SW_SHOW)

    ; Boucle avec fin
    While not $bEndScript
        Sleep(10)
    WEnd

    GUIDelete()
EndFunc   ;==>Example

Func OKPressed()
    MsgBox($MB_SYSTEMMODAL, "OK Press�", "ID=" & @GUI_CtrlId & " WinHandle=" & @GUI_WinHandle & " CtrlHandle=" & @GUI_CtrlHandle)
EndFunc   ;==>OKPressed

Func CancelPressed()
    MsgBox($MB_SYSTEMMODAL, "Cancel Press�", "ID=" & @GUI_CtrlId & " WinHandle=" & @GUI_WinHandle & " CtrlHandle=" & @GUI_CtrlHandle)
EndFunc   ;==>CancelPressed

Func SpecialEvents()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE
            MsgBox($MB_SYSTEMMODAL, "Close Press�", "ID=" & @GUI_CtrlId & " WinHandle=" & @GUI_WinHandle)
            $bEndScript = True

        Case $GUI_EVENT_MINIMIZE
            MsgBox($MB_SYSTEMMODAL, "Fen�tre Minimis�e", "ID=" & @GUI_CtrlId & " WinHandle=" & @GUI_WinHandle)

        Case $GUI_EVENT_RESTORE
            MsgBox($MB_SYSTEMMODAL, "Fen�tre Restaur�e", "ID=" & @GUI_CtrlId & " WinHandle=" & @GUI_WinHandle)

    EndSwitch
EndFunc   ;==>SpecialEvents