Functions > ObjCOM >

ObjCreate

Cr�e une r�f�rence � un objet COM � partir d'un nom de classe donn�.

ObjCreate ( "classname" [, "servername" [, "username" [, "password"]]] )

Param�tres

classname	Le nom de la classe de l'objet dans le format suivant : "appname.objectype" Ou aussi, une repr�sentation cha�ne du CLSID.
servername	[optionnel] Nom d'un ordinateur distant � partir duquel l'objet doit �tre obtenu.
username	[optionnel] Code utilisateur sur l'ordinateur distant. Vous devez entrer ce code dans le format "ordinateur\usercode" ou "domaine\usercode".
password	[optionnel] Mot de passe pour le code utilisateur sur l'ordinateur distant.

Valeur de retour

Succ�s:	Retourne l'objet.
�chec:	D�finit @error <> 0.

Remarques

Utilisez ObjCreate() si vous voulez avoir une nouvelle instance de l'application r�f�renc�.
Si vous souhaitez vous connecter � un processus existant, utilisez � la place ObjGet().

Gardez � l'esprit que tous les ordinateurs ont le m�me ensemble d'Objets. Donc testez toujours les erreurs apr�s un appel de ObjCreate(). Pour tester les erreurs utilisez ObjEvent() .

Les conditions suivantes s'appliquent si vous voulez acc�der � des objets sur des ordinateurs distants:

L'utilisateur qui ex�cute le script doit avoir des droits appropri�s.
L'Objet sur l'ordinateur distant doit supporter DCOM (Distributed COM)
L'ordinateur distant doit avoir les services 'Remote Registry Service' et 'File and Printer sharing' en cours d'ex�cution.

Consultez R�f�rence Obj/COM pour plus d'informations sur les objets.

En relation

GUICtrlCreateObj, IsObj, ObjEvent, ObjGet, ObjName

Exemples

Exemple 1

#include <MsgBoxConstants.au3>

; Compte le nombre de fen�tres shell ouvertes

Local $oShell = ObjCreate("shell.application") ; Obtient l'objet Shell Windows
Local $oShellWindows = $oShell.windows ; Obtient la collection de Windows shell ouvertes

If IsObj($oShellWindows) Then
    Local $sString = "" ; Cha�ne � afficher

    For $oWnd In $oShellWindows ; Compte toutes les fen�tres shell existantes
        $sString &= $oWnd.LocationName & @CRLF
    Next

    MsgBox($MB_SYSTEMMODAL, "", "Shell Windows:" & @CRLF & "Vous avez les fen�tres Shell suivantes:" & @CRLF & @CRLF & $sString)
EndIf

Exemple 2

#include <MsgBoxConstants.au3>

; Ouvre MediaPlayer sur un ordinateur distant

Local $oRemoteMedia = ObjCreate("MediaPlayer.MediaPlayer.1", "nom-de-ordinateur-distant")

If Not @error Then
    MsgBox($MB_SYSTEMMODAL, "Test ObjCreate Distant", "ObjCreate() de l'objet Mediaplayer distant r�ussi !")
    $oRemoteMedia.Open(@WindowsDir & "\media\tada.wav") ; Joue un son si le fichier est pr�sent
Else
    MsgBox($MB_SYSTEMMODAL, "Test ObjCreate Distant", "Echec de cr�ation de l'objet distant.  Code d'erreur: " & Hex(@error, 8))
EndIf