Functions > GUI > GUICtrlCreate >

GUICtrlCreateObj

Cr�e un contr�le ActiveX pour une GUI.

GUICtrlCreateObj ( ObjectVar, left, top [, width [, height]] )

Param�tres

ObjectVar Variable qui pointe sur un objet pr�c�demment ouvert
left Coordonn�e X du coin sup�rieur gauche du contr�le. Si -1 est utilis�, X sera calcul�e en accord avec GUICoordMode.
top Coordonn�e Y du coin sup�rieur gauche du contr�le. Si -1 est utilis�, Y sera calcul�e en accord avec GUICoordMode.
width [optionnel] Largeur du contr�le (par d�faut, la largeur utilis�e pr�c�demment ).
height [optionnel] Hauteur du contr�le (par d�faut, la hauteur pr�c�demment utilis�e ).

Valeur de retour

Succ�s: Retourne l'ID du nouveau contr�le.
�chec: Retourne 0.

Remarques

Cette fonction tente d'int�grer un 'contr�le ActiveX' ou un 'Document Object' dans une GUI.
Pas tous les contr�les peuvent �tre int�gr�s. Ils doivent supporter au moins une interface 'IDispatch'.

Consultez Obj/COM Reference pour plus d'informations sur les objets.

'Document Objects' ne sera visible que si le style Windows $WS_CLIPCHILDREN a �t� utilis� dans GUICreate().

Les fonctions GUI GUICtrlRead() et GUICtrlSet n'ont aucun effet sur ce contr�le. L'objet ne peut �tre contr�l�e qu'en utilisant des 'm�thodes' ou 'propri�t�s' de l'objet $ObjectVar.

En relation

IsObj, ObjCreate, ObjEvent, ObjGet

Exemple

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

; Exemple simple: Incorporation d'un objet Internet Explorer dans une GUI AutoIt
; Consultez aussi : http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/internetexplorer.asp
Func Example()
    Local $idButton_Back, $idButton_Forward
    Local $idButton_Home, $idButton_Stop 

    Local $oIE = ObjCreate("Shell.Explorer.2")

    ; Cr�e une GUI simple pour notre r�sultat
    GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
    GUICtrlCreateObj($oIE, 10, 40, 600, 360)
    $idButton_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
    $idButton_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
    $idButton_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
    $idButton_Stop = GUICtrlCreateButton("Stop", 330, 420, 100, 30)

    GUISetState(@SW_SHOW) ; Affiche l'interface utilisateur

    $oIE.navigate("http://www.autoitscript.com")

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg()
    While $idMsg <> $GUI_EVENT_CLOSE
        Switch $idMsg
            Case $idButton_Home
                $oIE.navigate("http://www.autoitscript.com")
            Case $idButton_Back
                $oIE.GoBack
            Case $idButton_Forward
                $oIE.GoForward
            Case $idButton_Stop
                $oIE.Stop
        EndSwitch
        $idMsg = GUIGetMsg()
    WEnd

    GUIDelete()
EndFunc   ;==>Example