Functions > Tray >

TrayCreateMenu

Cr�e un contr�le menu dans la zone de notification.

TrayCreateMenu ( "sub/menutext" [, menuID = -1 [, menuentry = -1]] )

Param�tres

sub/menutext Le texte du menu ou du sous-menu.
menuID [optionnel] Si d�fini, vous permet de cr�er un sous-menu dans le menu r�f�renc�. Par d�faut, -1 (fait r�f�rence au premier niveau du menu).
menuentry [optionnel] Vous permet de d�finir le nombre d'entr�es � cr�er. Les entr�es sont num�rot�es � partir de 0. Par d�faut -1 (en bas).

Valeur de retour

Succ�s: Retourne l'identifiant (controlID) du nouveau menu de la zone de notification.
�chec: Retourne 0.

En relation

TrayGetMsg, TrayItemDelete, TrayItemSetState, TrayItemSetText

Exemple

#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.

; Les items du menu de la zone de notification, par d�faut, ne seront pas affich�s et les items 
; ne seront pas coch�s quand ils seront s�lectionn�s. Ce sont les options 1 et 2 de TrayMenuMode.
Opt("TrayMenuMode", 3) 

Example()

Func Example()
    Local $iSettings = TrayCreateMenu("Settings") ; Cr�e un sous-menu du menu de la zone de notification avec deux sous-items.
    Local $iDisplay = TrayCreateItem("Display", $iSettings)
    Local $iPrinter = TrayCreateItem("Printer", $iSettings)
    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu de la barre.

    Local $iASlash, $sPath, $iMsg = TrayGetMsg()
    While $iMsg <> $idExit
        Switch $iMsg
            Case $idAbout 
                ; Affiche une bo�te de message � propos de la version et 
                ; du chemin d'installation de l'ex�cutable AutoIt.

                ; Recherche de droite � gauche l'antislash qui marque la fin du chemin
                $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
                ; Extrait le chemin seul, sans le nom, ni '\'
                $sPath = StringLeft(@AutoItExe, $iASlash - 1)

                MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Chemin d'installation: " & $sPath) 

            Case $iDisplay, $iPrinter
                MsgBox($MB_SYSTEMMODAL, "", "Un item d'un sous-menu a �t� s�lectionn� dans le menu de la zone de notification.")

        EndSwitch

        $iMsg = TrayGetMsg()
    WEnd
EndFunc   ;==>Example