Functions > Tray >

TraySetIcon

Charge/D�finit une ic�ne donn�e de la zone de notification.

TraySetIcon ( [filename [, iconID]] )

Param�tres

filename [optionnel] Le nom de l'ic�ne � afficher dans la zone de notification.
iconID [optionnel] Identifiant de l'ic�ne si le fichier contient plusieurs ic�nes.

Valeur de retour

Aucune.

Remarques

Pour d�finir l'ic�ne par d�faut, utilisez la fonction sans param�tre TraySetIcon().

Passez un nombre positif, pour faire r�f�rence � l'�quivalent cha�ne du nom de l'ic�ne.
Passez un nombre n�gatif, pour obtenir un comportement d'�index� de base 1. Les ic�nes de certaines Dll peuvent �tre extraites seulement avec des nombres n�gatifs.

Le param�tre filename peut �tre "blank", "info", "question", "stop" ou "warning" afin de s�lectionner l'ic�ne standard correspondante.

En relation

TraySetPauseIcon, TraySetState

Exemple

#NoTrayIcon
#include <TrayConstants.au3> ; Pour la constante $TRAY_ICONSTATE_SHOW.

; Les items de menu, par d�faut, ne seront pas affich�s et 
; les items ne seront pas coch�s lorsqu'ils seront s�lectionn�s. 
; Ce sont les options 1 et 2 de TrayMenuMode.
Opt("TrayMenuMode", 3)

Example()

Func Example()
    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu de la zone de notification.

    Local $hTimer = TimerInit() ; D�marre un chrono et stocke Le handle dans une variable.
    Local $fDiff = 0, $iIndex = 0

    Do
        ; Temps �coul� depuis l'appel pr�c�dent de TimerInit 
        $fDiff = TimerDiff($hTimer)

        ; Si le temps �coul� est sup�rieure � 1 seconde, alors change l'ic�ne du menu de la zone de notification.
        If $fDiff > 1000 Then
            ; Utilise un nombre n�gatif pour la num�rotation ordinale. 
            $iIndex = -Random(0, 100, 1)

            ; D�finit l'info-bulle du menu avec des informations sur l'index de l'ic�ne.
            TraySetToolTip("Currently using the icon shell32.dll, " & $iIndex & ".")

            ; D�finit l'ic�ne du menu � l'aide de shell32.dll et d'un num�ro al�atoire d'index.
            TraySetIcon("shell32.dll", $iIndex)

            ; R�initialise le compteur.
            $hTimer = TimerInit()

        EndIf

    Until TrayGetMsg() = $idExit
EndFunc   ;==>Example