UDF > Clipboard >

_ClipBoard_GetDataEx

R�cup�re les donn�es du presse-papiers dans un format sp�cifi�

#include <Clipboard.au3>
_ClipBoard_GetDataEx ( [$iFormat = 1] )

Param�tre

$iFormat [optionnel] Sp�cifie un format de presse-papiers:
$CF_TEXT - Format texte
$CF_BITMAP - Handle d'une image bitmap (HBITMAP)
$CF_METAFILEPICT - Handle d'un m�tafichier d'image (METAFILEPICT)
$CF_SYLK - Format Microsoft Symbolic Link (SYLK)
$CF_DIF - Format Data Interchange de Software Arts
$CF_TIFF - Format Tagged Image File
$CF_OEMTEXT - Format texte contenant des caract�res dans le jeu de caract�res OEM
$CF_DIB - Structure de BITMAPINFO suivie par les bits du bitmap
$CF_PALETTE - Handle d'une palette de couleurs
$CF_PENDATA - Donn�es pour les extensions de crayon � Pen Computing
$CF_RIFF - Repr�sente les donn�es audio au format RIFF
$CF_WAVE - Repr�sente les donn�es audio au format WAVE
$CF_UNICODETEXT - Format texte Unicode
$CF_ENHMETAFILE - Handle d'un m�tafichier �tendu (HENHMETAFILE)
$CF_HDROP - Handle d'un type HDROP qui identifie une liste de fichiers
$CF_LOCALE - Handle d'un identifiant de param�tres r�gionaux associ�s au texte du presse-papiers
$CF_DIBV5 - Structure BITMAPV5HEADER suivie par les couleurs du bitmap et des bits du bitmap
$CF_OWNERDISPLAY - Format d'affichage propri�taire
$CF_DSPTEXT - Format d'affichage de texte associ� � un format priv�
$CF_DSPBITMAP - Format d'affichage de bitmap associ� � un format priv�
$CF_DSPMETAFILEPICT - Format d'affichage de m�tafichier d'image associ� � un format priv�
$CF_DSPENHMETAFILE - Format d'affichage de m�tafichier am�lior� associ� � un format priv�

Valeur de retour

Succ�s: Retourne le handle de l'objet presse-papiers dans le format sp�cifi�
�chec: Retourne 0

Remarque

Le presse-papiers contr�le le handle que la fonction _ClipBoard_GetData() retourne, pas l'application.
Vous devez copier imm�diatement les donn�es. L'application ne doit pas lib�rer le handle ni le verrouiller.
L'application ne doit pas utiliser le handle apr�s des appels des fonctions _ClipBoard_Empty() ou _ClipBoard_Close(), or apr�s l'appel de la fonction _ClipBoard_SetData() avec le m�me format de presse-papiers.

En relation

_ClipBoard_GetData, _ClipBoard_SetData

Voir aussi

Consultez GetClipboardData dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $id_SetData, $id_GetData, $hMemory, $tData

    ; Cr�e une GUI
    $hGUI = GUICreate("Clipboard", 600, 450)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    $id_SetData = GUICtrlCreateButton("Set ClipBoard Data", 150, 410, 120, 30)
    $id_GetData = GUICtrlCreateButton("Get ClipBoard Data", 300, 410, 120, 30)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $id_SetData
                _ClipBoard_SetData("ClipBoard Library")
            Case $id_GetData
                ; Ouvre le presse-papiers
                If _ClipBoard_Open($hGUI) Then
                    ; Lit le texte du presse-papiers
                    $hMemory = _ClipBoard_GetDataEx($CF_TEXT)
                    If $hMemory = 0 Then _WinAPI_ShowError("_ClipBoard_GetDataEx a �chou�")
                    $tData = DllStructCreate("char Text[8192]", $hMemory)
                    MemoWrite(DllStructGetData($tData, "Text"))

                    ; Ferme le presse-papiers
                    _ClipBoard_Close()
                Else
                    _WinAPI_ShowError("_ClipBoard_Open a �chou�")
                EndIf
        EndSwitch
    Until $iMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite