UDF > Crypt >


_Crypt_DecryptFile

D�chiffre un fichier avec la cl� et l'algorithme sp�cifi�s

#include <Crypt.au3>
_Crypt_DecryptFile ( $sSourceFile, $sDestinationFile, $vCryptKey, $iAlgID )

Param�tres

$sSourceFile Fichier � traiter
$sDestinationFile Fichier o� sera enregistr� le fichier trait�
$vCryptKey Mot de passe ou descripteur (handle)'d'une cl� si l'indicateur CALG_USERKEY est sp�cifi�
$iAlgID L'algorithme � utiliser. Voir _Crypt_DeriveKey().

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0.
@error: 10+ - Impossible de cr�er la cl�
2 - Impossible d'ouvrir le fichier source
3 - Impossible d'ouvrir le fichier de destination
400+ - Impossible de d�chiffrer la partie finale
500+ - Impossible de d�chiffrer la partie

En relation

_Crypt_DeriveKey, _Crypt_EncryptFile

Exemple

#include <ComboConstants.au3>
#include <Crypt.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Example()

Func Example()
    Local $iAlgorithm = $CALG_RC4

    Local $hGUI = GUICreate("D�chiffreur de fichiers", 425, 100)
    Local $idSourceInput = GUICtrlCreateInput("", 5, 5, 200, 20)
    Local $idSourceBrowse = GUICtrlCreateButton("...", 210, 5, 35, 20)

    Local $idDestinationInput = GUICtrlCreateInput("", 5, 30, 200, 20)
    Local $idDestinationBrowse = GUICtrlCreateButton("...", 210, 30, 35, 20)

    GUICtrlCreateLabel("Mot de passe :", 5, 60, 200, 20)
    Local $idPasswordInput = GUICtrlCreateInput("", 5, 75, 200, 20)

    Local $idCombo = GUICtrlCreateCombo("", 210, 75, 100, 20, $CBS_DROPDOWNLIST)
    GUICtrlSetData($idCombo, "3DES (168bit)|AES (128bit)|AES (192bit)|AES (256bit)|DES (56bit)|RC2 (128bit)|RC4 (128bit)", "RC4 (128bit)")
    Local $idDecrypt = GUICtrlCreateButton("D�chiffrer", 355, 70, 65, 25)
    GUISetState(@SW_SHOW, $hGUI)

    Local $sDestinationRead = "", $sFilePath = "", $sPasswordRead = "", $sSourceRead = ""
    Local $iMsg

    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $idSourceBrowse
                $sFilePath = FileOpenDialog("S�lectionner un fichier � d�chiffrer.", "", "All files (*.*)") ; S�lectionne un fichier � d�chiffrer.
                If @error Then
                    ContinueLoop
                EndIf
                GUICtrlSetData($idSourceInput, $sFilePath) ; D�finit l'inputbox avec le chemin du fichier.

            Case $idDestinationBrowse
                $sFilePath = FileSaveDialog("Enregistrer le fichier sous...", "", "All files (*.*)") ; S�lectionner un fichier pour enregistrer les donn�es d�chiffr�es.
                If @error Then
                    ContinueLoop
                EndIf
                GUICtrlSetData($idDestinationInput, $sFilePath) ; D�finit l'inputbox avec le chemin du fichier.

            Case $idCombo ; V�rifie si le combobox est s�lectionn� et r�cup�re le bon algorithme.
                Switch GUICtrlRead($idCombo) ; Lit la s�lection du combobox.
                    Case "3DES (168bit)"
                        $iAlgorithm = $CALG_3DES

                    Case "AES (128bit)"
                        $iAlgorithm = $CALG_AES_128

                    Case "AES (192bit)"
                        $iAlgorithm = $CALG_AES_192

                    Case "AES (256bit)"
                        $iAlgorithm = $CALG_AES_256

                    Case "DES (56bit)"
                        $iAlgorithm = $CALG_DES

                    Case "RC2 (128bit)"
                        $iAlgorithm = $CALG_RC2

                    Case "RC4 (128bit)"
                        $iAlgorithm = $CALG_RC4

                EndSwitch

            Case $idDecrypt
                $sSourceRead = GUICtrlRead($idSourceInput) ; Lit le chemin du fichier source dans l'input.
                $sDestinationRead = GUICtrlRead($idDestinationInput) ; Lit le chemin du fichier de destination dans l'input.
                $sPasswordRead = GUICtrlRead($idPasswordInput) ; Lit le mot de passe dans l'input.
                If StringStripWS($sSourceRead, $STR_STRIPALL) <> "" And StringStripWS($sDestinationRead, $STR_STRIPALL) <> "" And StringStripWS($sPasswordRead, $STR_STRIPALL) <> "" And FileExists($sSourceRead) Then ; V�rifie que le fichier � d�chiffrer existe et qu'un mot de passe a �t� d�fini.
                    If _Crypt_DecryptFile($sSourceRead, $sDestinationRead, $sPasswordRead, $iAlgorithm) Then ; D�chiffre le fichier.
                        MsgBox($MB_SYSTEMMODAL, "Succ�s", "Op�ration r�ussie.")
                    Else
                        Switch @error
                            Case 2
                                MsgBox($MB_SYSTEMMODAL, "Erreur", "Impossible d'ouvrir le fichier source.")
                            Case 3
                                MsgBox($MB_SYSTEMMODAL, "Erreur", "Impossible d'ouvrir le fichier de destination.")
                            Case 30
                                MsgBox($MB_SYSTEMMODAL, "Erreur", "Impossible de cr�er la cl�.")

                            Case 400 Or 500
                                MsgBox($MB_SYSTEMMODAL, "Erreur", "Erreur de d�chiffrement.")
                            
                            Case Else
                                MsgBox($MB_SYSTEMMODAL, "Error", "Unexpected @error = " & @error)

                        EndSwitch
                    EndIf
                Else
                    MsgBox($MB_SYSTEMMODAL, "Erreur", "Veuillez vous assurer que l'information appropri�e a �t� entr�e correctement.")
                EndIf
        EndSwitch
    Until  $iMsg = $GUI_EVENT_CLOSE

    GUIDelete($hGUI) ; Supprime la GUI pr�c�dente et tous ses contr�les.
EndFunc   ;==>Example