Fonction _FTP_ProgressDownload

T�l�charge un fichier en mode binaire en affichant une barre de progression ou en appelant une fonction d�finie par l'utilisateur

#include <FTPEx.au3>
_FTP_ProgressDownload ( $hFTPSession, $sLocalFile, $sRemoteFile [, $hFunctionToCall = 0] )

Param�tres

Valeur de retour

Remarque

Informations sur $hFunctionToCall:
    Param�tre: $iPercentage - Le pourcentage de la progression
    Valeurs de retour:
        Continue le t�l�chargement - 1
        Abandonne le t�l�chargement - z�ro ou inf�rieur � z�ro par exemple 0 ou -1
    Ces valeurs sont retourn�es par _FTP_ProgressDownload(), de sorte que vous pouvez r�agir sur diff�rentes actions comme l'Abandon par l'utilisateur, la fermeture de l'App ou le TimeOut du processus.

Exemples

Exemple 1

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <ProgressConstants.au3>

Global $g_sRemoteFile = "/pub/software/databases/rt/SRPMS/ucs-local-modperl-2.0.3-1.src.rpm"
Global $g_sLocalFile = @TempDir & "\temp.tmp"
FileDelete($g_sLocalFile)

Local $sServer = 'ftp.csx.cam.ac.uk'
Local $sUsername = ''
Local $sPass = ''

Local $hInternetSession = _FTP_Open('MyFTP Control')
; Passive permet plus de protections FTP pour r�pondre
Local $hFTPSession = _FTP_Connect($hInternetSession, $sServer, $sUsername, $sPass, 1)

Example()

_FTP_Close($hInternetSession)

Func Example()
    Local $sFunctionToCall = "_UpdateProgress"
    ProgressOn("Download Progress", $g_sRemoteFile)
    _FTP_ProgressDownload($hFTPSession, $g_sLocalFile, $g_sRemoteFile, $sFunctionToCall)
    ProgressOff()
EndFunc   ;==>Example

Func _UpdateProgress($iPercent)
    ProgressSet($iPercent, Int($iPercent) & "%")
    If _IsPressed("77") Then Return 0 ; Abandon sur F8
    Return 1 ; 1 pour continuer t�l�charger
EndFunc   ;==>_UpdateProgress

Exemple 2

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

Global $g_sRemoteFile = "/pub/software/databases/rt/SRPMS/ucs-local-modperl-2.0.3-1.src.rpm"
Global $g_sLocalFile = @TempDir & "\temp.tmp"
FileDelete($g_sLocalFile)

Local $sServer = 'ftp.csx.cam.ac.uk'
Local $sUsername = ''
Local $sPass = ''

Local $hInternetSession = _FTP_Open('MyFTP Control')
; Passive permet plus de protections FTP pour r�pondre
Local $hFTPSession = _FTP_Connect($hInternetSession, $sServer, $sUsername, $sPass, 1)

Global $g_idProgressBarCtrl, $g_idBtn_Cancel
Example()

_FTP_Close($hInternetSession)

Func Example()
    ; Cr�e une GUI
    GUICreate("My GUI download Progressbar", 220, 100, 100, 200)
    GUICtrlCreateLabel($g_sRemoteFile, 10, 10)
    $g_idProgressBarCtrl = GUICtrlCreateProgress(10, 40, 200, 20, $PBS_SMOOTH)
    GUICtrlSetColor(-1, 32250); ne fonctionne pas avec les styles de Windows XP
    $g_idBtn_Cancel = GUICtrlCreateButton("Cancel", 75, 70, 70, 20)
    GUISetState(@SW_SHOW)

    Local $sFunctionToCall = "_UpdateGUIProgressBar"
    _FTP_ProgressDownload($hFTPSession, $g_sLocalFile, $g_sRemoteFile, $sFunctionToCall)
EndFunc   ;==>Example

Func _UpdateGUIProgressBar($iPercent)
    GUICtrlSetData($g_idProgressBarCtrl, $iPercent)
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit -1 ; _FTP_DownloadProgress s'interrompt avec -1, de sorte que vous pouvez quitter votre application apr�s
        Case $g_idBtn_Cancel
            Exit -2 ; Juste Annuler, sans valeur sp�ciale de retour
    EndSwitch
    Return 1 ; Sinon, poursuivre le t�l�chargement
EndFunc   ;==>_UpdateGUIProgressBar

Succ�s:	Retourne 1.
�chec:	Retourne 0 et d�finit @error <> 0.
@error:	-1 - Le fichier local n'a pas pu �tre cr�� -2 - Impossible d'obtenir la taille du fichier distant -3 - L'ouverture du fichier distant a �chou� -4 - La lecture du fichier distant a �chou� -5 - La fermeture du fichier distant a �chou� -6 - Le t�l�chargement a �t� interrompu par PercentageFunc et retourne � la fonction appel�e -7 - L'�criture du fichier local a �chou�

$hFTPSession	Handle retourn� par _FTP_Connect().
$sLocalFile	Le fichier local � cr�er.
$sRemoteFile	Le fichier source distant.
$hFunctionToCall	[optionnel] Une variable affect�e par la fonction d�finie par l'utilisateur pour mettre � jour une barre de progression ou r�agir � l'interaction de l'utilisateur, comme l'interruption ou � la sortie du processus. Par d�faut = Aucun. Voir Remarques.