UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsDrawImagePointsRect

Dessine une image

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawImagePointsRect ( $hGraphics, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY, $nSrcX, $nSrcY, $nSrcWidth, $nSrcHeight [, $hImageAttributes = 0 [, $iUnit = 2]] )

Param�tres

$hGraphics Handle de l'objet Graphics
$hImage Handle de l'objet Image
$nULX La coordonn�e X du coin sup�rieur gauche de l'image source
$nULY La coordonn�e Y du coin sup�rieur gauche de l'image source
$nURX La coordonn�e X du coin sup�rieur droit de l'image source
$nURY La coordonn�e Y du coin sup�rieur droit de l'image source
$nLLX La coordonn�e X du coin inf�rieur gauche de l'image source
$nLLY La coordonn�e Y du coin inf�rieur gauche de l'image source
$nSrcX La coordonn�e X du coin sup�rieur gauche de la portion de l'image source qui doit �tre dessin�e
$nSrcY La coordonn�e Y du coin sup�rieur gauche de la portion de l'image source qui doit �tre dessin�e
$nSrcWidth La largeur de l'image source qui doit �tre dessin�e
$nSrcHeight La hauteur de l'image source qui doit �tre dessin�e
$hImageAttributes [optionnel] Handle de l'objet ImageAttributes qui sp�cifie les attributs de couleur et de taille de l'image qui doit �tre dessin�e
$iUnit [optionnel] Unit� de mesure:
    0 - Coordonn�es mondiales, une unit� non physique
    1 - Unit� d'affichage
    2 - Unit� de 1 pixel
    3 - Unit� de 1 point ou 1/72 pouce
    4 - Unit� de 1 pouce
    5 - Unit� de 1/300 pouce
    6 - Unit� de 1 millim�tre

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_GraphicsDrawImage

Voir aussi

Consultez GdipDrawImagePointsRect dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Support d'ex�cution X64
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"

    ; Obtient le dossier d'installation de AutoIt
    Local $sRegPath = "HKLM\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt"

    Local $sFile = RegRead($sRegPath, "InstallDir") & "\Examples\GUI\logo4.gif"
    If Not FileExists($sFile) Then
        MsgBox(BitOR($MB_SYSTEMMODAL, $MB_ICONHAND), "", $sFile & " not found!", 30)
        Return False
    EndIf

    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile) ; Cr�e un objet image li� � un fichier
    If @error Then
        _GDIPlus_Shutdown()
        MsgBox(BitOR($MB_SYSTEMMODAL, $MB_ICONHAND), "", "An error has occured - unable to load image!", 30)
        Return False
    EndIf

    Local $hGUI, $hGraphic, $iImgW, $iImgH

    ; Cr�e une GUI
    $hGUI = GUICreate("GDI+", 800, 400)
    GUISetState(@SW_SHOW)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�e un objet graphics � partir du handle d'une fen�tre

    $iImgW = _GDIPlus_ImageGetWidth($hImage)
    $iImgH = _GDIPlus_ImageGetHeight($hImage)

    _GDIPlus_GraphicsDrawImagePointsRect($hGraphic, $hImage, 100, 10, 300, 60, 90, 160, 0, 0, $iImgW * 0.45, $iImgH)
    _GDIPlus_GraphicsDrawImagePointsRect($hGraphic, $hImage, 300, 60, 360, 30, 290, 210, $iImgW * 0.45, 0, $iImgW * 0.2, $iImgH)
    _GDIPlus_GraphicsDrawImagePointsRect($hGraphic, $hImage, 360, 30, 560, 80, 350, 180, $iImgW * 0.65, 0, $iImgW * 0.35, $iImgH)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Lib�re les ressources
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example