UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsFillPie

Remplit un secteur angulaire

#include <GDIPlus.au3>
_GDIPlus_GraphicsFillPie ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hBrush = 0] )

Param�tres

$hGraphics Handle de l'objet Graphics
$nX La coordonn�e X du coin sup�rieur gauche du rectangle qui d�limite l'ellipse dans laquelle extraire le secteur angulaire
$nY La coordonn�e Y du coin sup�rieur gauche du rectangle qui d�limite l'ellipse dans laquelle extraire le secteur angulaire
$nWidth La largeur du rectangle qui d�limite l'ellipse dans laquelle dessiner le secteur angulaire
$nHeight La hauteur du rectangle qui d�limite l'ellipse dans laquelle dessiner le secteur angulaire
$fStartAngle L'angle, en degr�s, entre l'axe X et le point de d�part de l'arc qui d�finit le secteur angulaire.
Une valeur positive indique une rotation dans le sens horaire.
$fSweepAngle L'angle, en degr�s, entre les points de d�but et de fin de l'arc qui d�finit le secteur angulaire.
Une valeur positive indique une rotation dans le sens horaire.
$hBrush [optionnel] Handle de l'objet Brush (pinceau) qui est utilis� pour remplir le secteur angulaire. Si 0, un pinceau noir sera utilis�.

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipFillPie dans la Librairie MSDN.

Exemples

Exemple 1

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic

    ; Cr�e GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Remplit un secteur angulaire
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsFillPie($hGraphic, 150, 80, 100, 100, 45, 90)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Exemple 2

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Cr�e une fen�tre de test
    GUISetBkColor($iBgColor, $hGUI) ; D�finit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�e un objet Graphics � partir du handle de la fen�tre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; D�finit pour l'objet graphique la qualit� de rendu antialiasing
    Local $hBrush = _GDIPlus_BrushCreateSolid(0xFF8080A0) ; Format de couleur AARRGGBB (hex)
    _GDIPlus_GraphicsFillPie($hGraphics, 100.5, 0.5, 400.75, 400.125, 45, 90, $hBrush)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_PenDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example