UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsSetCompositingQuality

D�finit la qualit� de composition d'un objet Graphics

#include <GDIPlus.au3>
_GDIPlus_GraphicsSetCompositingQuality ( $hGraphics, $iCompositionQuality )

Param�tres

$hGraphics Handle de l'objet Graphics
$iCompositionQuality Qualit� de composition:
        0 - La correction gamma n'est pas appliqu�e.
        1 - La correction gamma n'est pas appliqu�e. Grande vitesse, faible qualit�.
        2 - La correction gamma est appliqu�e. Composition de haute qualit� et de haute rapidit�.
        3 - La correction gamma est appliqu�e.
        4 - La correction gamma n'est pas appliqu�e. Des valeurs lin�aires sont utilis�es.

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_GraphicsGetCompositingQuality

Voir aussi

Consultez GdipSetCompositingQuality dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $iQuality1, $iQuality2, $hMatrix

    ; Cr�e GUI
    $hGUI = GUICreate("GDI+", 800, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�ez un objet graphique � partir d'un handle fen�tre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphic, 0xFF6600AA)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 380, 360)

    $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFFFF)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0)
    _GDIPlus_PathBrushSetSigmaBlend($hBrush, 1)
    _GDIPlus_PathBrushSetFocusScales($hBrush, 0.7, 0.7)
    _GDIPlus_GraphicsFillPath($hGraphic, $hPath, $hBrush)

    $iQuality1 = _GDIPlus_GraphicsGetCompositingQuality($hGraphic)

    $hMatrix = _GDIPlus_MatrixCreate()
    _GDIPlus_MatrixTranslate($hMatrix, 400, 0)
    _GDIPlus_PathTransform($hPath, $hMatrix)
    _GDIPlus_PathBrushSetTransform($hBrush, $hMatrix)

    _GDIPlus_GraphicsSetCompositingQuality($hGraphic, 3)
    _GDIPlus_GraphicsFillPath($hGraphic, $hPath, $hBrush)
    $iQuality2 = _GDIPlus_GraphicsGetCompositingQuality($hGraphic)

    _GDIPlus_GraphicsDrawString($hGraphic, "CompositingQuality = " & $iQuality1, 10, 380)
    _GDIPlus_GraphicsDrawString($hGraphic, "CompositingQuality = " & $iQuality2, 420, 380)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_MatrixDispose($hMatrix)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example