UDF > GDIPlus > Image >

_GDIPlus_ImageGetFlags

Retourne l'�num�ration des attributs de donn�es de pixels contenus dans une image

#include <GDIPlus.au3>
_GDIPlus_ImageGetFlags ( $hImage )

Param�tre

$hImage Handle de l'objet image

Valeur de retour

Succ�s: Retourne un tableau avec le format suivant:
    [0] - Ensemble de flags entiers d'attributs de donn�es de pixels
    [1] - Cha�ne d'attributs de donn�es de pixel s�par�es par le d�limiteur "|"
�chec: D�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).
@error: 10 - Les flags ne peuvent pas �tre r�cup�r�es
11 - Le handle de l'image est invalide
12 - Pas de donn�e de pixels

Remarque

Utilisez BitAND sur les flags entiers retourn�s avec les constantes $GDIP_IMAGEFLAGS_*.

En relation

_GDIPlus_ImageGetPixelFormat

Voir aussi

Consultez GdipGetImageFlags dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hBitmap, $hImage, $aRet

    ; Cr�e une GUI
    GUICreate("GDI+", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialise la biblioth�que GDI+
    _GDIPlus_Startup()

    ; Capture un bitmap 32 bits
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Affiche l'�num�ration des attributs de donn�es de pixels de la capture d'�cran
    $aRet = _GDIPlus_ImageGetFlags($hImage)
    $aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
    MemoWrite("Image pixel data attributes of screen capture: " & $aRet[1]); 
    MemoWrite(); 
    MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]); 
    MemoWrite(); 

    ; Enregistre le bitmap de la capture d'�cran dans un fihier
    _GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Nettoie les ressources
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Charge le bitmap de la capture d'�cran � partir du fichier
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Affiche l'�num�ration des attributs de donn�es de pixels du fichier enregistr�
    $aRet = _GDIPlus_ImageGetFlags($hImage)
    $aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
    MemoWrite("Image pixel data attributes of saved file: " & $aRet[1]); 
    MemoWrite(); 
    MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]); 

    ; Nettoie les ressources
    _GDIPlus_ImageDispose($hImage)

    ; Arr�te la biblioth�que GDI+
    _GDIPlus_Shutdown()

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; �crit une ligne dans le contr�le m�mo
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite