UDF > GDIPlus > LineBrush >

_GDIPlus_LineBrushCreateFromRect

Cr�e un pinceau � d�grad� lin�aire sur la base d'un rectangle, des couleurs de d�but et de fin, et de l'orientation

#include <GDIPlus.au3>
_GDIPlus_LineBrushCreateFromRect ( $tRECTF, $iARGBClr1, $iARGBClr2 [, $iGradientMode = 0 [, $iWrapMode = 0]] )

Param�tres

$tRectF Structure $tagGDIPRECTF qui sp�cifie les points de d�but et de fin du d�grad�
$iARGBClr1 Composantes Alpha, Rouge, Vert et Bleu de la couleur de d�but de la ligne
$iARGBClr2 Composantes Alpha, Rouge, Vert et Bleu de la couleur de fin de la ligne
$iGradientMode [optionnel] La direction du d�grad�:
    0 - Direction horizontale de la gauche de l'�cran vers la droite de l'�cran,
    1 - Direction verticale depuis le haut de l'�cran vers le bas de l'�cran
    2 - Direction vers l'avant en diagonale � partir du coin sup�rieur gauche au coin inf�rieur droit de l'�cran
    3 - Direction vers l'arri�re en diagonale � partir du coin sup�rieur droit vers le coin inf�rieur gauche de l'�cran
$iWrapMode [optionnel] Indique comment un d�grad� est dispos� en mosa�que lorsqu'il est plus petit que la zone � remplir:
    0 - Dispose le d�grad� en mosa�que, sans sym�trie
    1 - Retourne le d�grad� horizontalement, puis le dispose en mosa�que
    2 - Retourne le d�grad� verticalement, puis le dispose en mosa�que
    3 - Retourne le d�grad� horizontalement et verticalement, puis le dispose en mosa�que
    4 - Le d�grad� n'est pas dispos� en mosa�que

Valeur de retour

Succ�s: Retourne le handle du nouvel objet LinearGradientBrush.
�chec: Retourne 0 et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez termin� avec l'objet, appelez _GDIPlus_BrushDispose() pour lib�rer les ressources de l'objet.

En relation

_GDIPlus_BrushDispose

Voir aussi

Consultez GdipCreateLineBrushFromRect dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $tRectF

    $hGUI = GUICreate("GDI+", 420, 320)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsClear($hGraphic, 0xFF000000)

    $tRectF = _GDIPlus_RectFCreate(10, 10, 400, 300)
    $hBrush = _GDIPlus_LineBrushCreateFromRect($tRectF, 0xFF000000, 0xFFFFFFFF, 2)
    _GDIPlus_LineBrushSetSigmaBlend($hBrush, 1)

    _GDIPlus_GraphicsFillRect($hGraphic, 10, 10, 400, 300, $hBrush)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example