UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushCreate

Cr�e un objet PathGradientBrush, pinceau � couleurs d�grad�es de trac� qui remplit l'int�rieur d'un objet GraphicsPath, � partir d'un tableau de points et d'un mode d'habillage

#include <GDIPlus.au3>
_GDIPlus_PathBrushCreate ( $aPoints [, $iWrapMode = 0] )

Param�tres

$aPoints Tableau de points qui sp�cifie la limite du trac� du pinceau
    [0][0] - Nombre de points
    [1][0] - Point 1, position X
    [1][1] - Point 1, position Y
    [2][0] - Point 2, position X
    [2][1] - Point 2, position Y
    [n][0] - Point n, position X
    [n][1] - Point n, position Y
$iWrapMode [optionnel] Indique comment un d�grad� est dispos� en mosa�que lorsqu'il est plus petit que la zone � remplir:
    0 - Dispose le d�grad� en mosa�que, sans sym�trie
    1 - Retourne le d�grad� horizontalement, puis le dispose en mosa�que
    2 - Retourne le d�grad� verticalement, puis le dispose en mosa�que
    3 - Retourne le d�grad� horizontalement et verticalement, puis le dispose en mosa�que
    4 - Le d�grad� n'est pas dispos� en mosa�que

Valeur de retour

Succ�s: Retourne le handle du nouvel objet PathGradientBrush.
�chec: Retourne 0 et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarques

Le d�grad� de couleurs est un ombrage de couleurs unies allant du point central du trac� � son bord ext�rieur. Les facteurs de m�lange, les positions et le style affectent les couleurs de d�but et de fin du d�grad� ainsi que la vitesse � laquelle la couleur change.
Les pinceaux � couleurs d�grad�es de trac� sont insensibles au mode de lissage (SmoothingMode).
Lorsque vous en avez termin� avec l'objet, appelez _GDIPlus_BrushDispose() pour lib�rer les ressources de l'objet.

En relation

_GDIPlus_BrushDispose

Voir aussi

Consultez GdipCreatePathGradient dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 600, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $aPoints[4][2] = [[3]]
    $aPoints[1][0] = 0
    $aPoints[1][1] = 0
    $aPoints[2][0] = 100
    $aPoints[2][1] = 30
    $aPoints[3][0] = 50
    $aPoints[3][1] = 80

    Local $hBrush = _GDIPlus_PathBrushCreate($aPoints, 3)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFFFF)

    Local $aColors[4] = [3]
    $aColors[1] = 0xFFFF0000
    $aColors[2] = 0xFF00FF00
    $aColors[3] = 0xFF0000FF
    _GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)

    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 600, 400, $hBrush)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example