UDF > GDIPlus > PathGradientBrush >

_GDIPlus_PathBrushSetLinearBlend

D�finit la mani�re de m�langer les couleurs d'un pinceau � couleurs d�grad�es de trac� pour cr�er un m�lange personnalis� selon sur une courbe en triangle

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetLinearBlend ( $hPathGradientBrush, $fFocus [, $fScale = 1] )

Param�tres

$hPathGradientBrush Handle de l'objet PathGradientBrush
$fFocus Nombre dans la gamme de 0,0 � 1,0 qui sp�cifie o� la couleur de centre sera � sa plus haute intensit�
$fScale [optionnel] Nombre compris entre 0.0 � 1.0 qui indique le pourcentage (/100) de la couleur de fin que le d�grad� atteindra progressivement par fusion avec la couleur de d�but du d�grad�. La valeur par d�faut est 1, ce qui signifie que la couleur de fin de zone est en pleine intensit�

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_PathBrushSetSigmaBlend

Voir aussi

Consultez GdipSetPathGradientLinearBlend dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 200, 180)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 100, 90)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF0000FF)
    _GDIPlus_PathBrushSetLinearBlend($hBrush, 0.25, 0.75)
    _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example