UDF > GDIPlus > StringFormat >

_GDIPlus_StringFormatCreate

Cr�e un objet StringFormat

#include <GDIPlus.au3>
_GDIPlus_StringFormatCreate ( [$iFormat = 0 [, $iLangID = 0]] )

Param�tres

$iFormat

[optionnel] Flags StringFormat. Peut �tre l'un ou plusieurs des �l�ments suivants:
    0x0001 - Indique que l'ordre de lecture est de droite � gauche
    0x0002 - Indique que les lignes individuelles de texte sont dessin�es verticalement sur le dispositif d'affichage
    0x0004 - Indique que les parties de caract�res sont autoris�s � recouvrir le rectangle de disposition de la cha�ne
    0x0020 - Indique que les caract�res Unicode de contr�le de la mise en page sont affich�es avec un caract�re repr�sentatif
    0x0400 - Indique qu'une autre police est utilis�e pour les caract�res qui ne sont pas pris en charge dans la police demand�e
    0x0800 - Indique que l'espace � la fin de chaque ligne est inclus dans une mesure de cha�ne (par d�faut MeasureString exclut cet espace)
    0x1000 - Indique que la c�sure du texte � la ligne suivante est d�sactiv�
    0x2000 - Indique que seules des lignes enti�res sont affich�es dans le rectangle de mise en page
    0x4000 - Indique que les caract�res recouvrant le rectangle de mise en page et le texte s'�tendant � l'ext�rieur du rectangle de mise en page peuvent s'afficher

$iLangID

[optionnel] La langue � utiliser

Valeur de retour

Succ�s:	Retourne le handle de l'objet StringFormat.
�chec:	Retourne 0 et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

L'objet StringFormat contient les informations relatives � la mise en page du texte (telles que l'alignement, l'orientation et les taquets de tabulation), les manipulations d'affichage (telles que l'insertion de points de s�lection et la substitution des formes nationales de chiffres).
Lorsque vous en avez termin� avec l'objet StringFormat, appelez _GDIPlus_StringFormatDispose() pour lib�rer les ressources.

En relation

_GDIPlus_StringFormatDispose, _GDIPlus_StringFormatSetAlign

Voir aussi

Consultez GdipCreateStringFormat dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; Cr�e une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine une cha�ne
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)

    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example