UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_GetListArray

R�cup�re, dans un tableau, tous les �l�ments de la liste d'un contr�le ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetListArray ( $hWnd )

Param�tre

$hWnd Handle du contr�le

Valeur de retour

Retourne un tableau dans le format suivant :
    [0] - Nombre d'�l�ments
    [1] - El�ment 1
    [2] - El�ment 2
    [n] - El�ment n

En relation

_GUICtrlComboBoxEx_GetList

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aItem, $hCombo

    ; Cr�e une GUI
    $hGUI = GUICreate("ComboBoxEx Get List Array", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)

    ; Obtient la liste
    $aItem = _GUICtrlComboBoxEx_GetListArray($hCombo)

    For $x = 1 To $aItem[0]
        MemoWrite($aItem[$x])
    Next

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contr�le m�mo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite