UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetCurSel

S�lectionne une cha�ne dans la liste d'une ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetCurSel ( $hWnd [, $iIndex = -1] )

Param�tres

$hWnd Handle du contr�le
$iIndex [optionnel] Sp�cifie l'index, compt� � partir de 0, de la cha�ne � s�lectionner

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarques

Si $iIndex est 1, toute la s�lection actuelle dans la liste est supprim� et le contr�le d'�dition est effac�.

Si $iIndex est sup�rieur au nombre d'�l�ments dans la liste ou si $iIndex est 1, la valeur de retour est -1 et la s�lection est annul�e.

En relation

_GUICtrlComboBoxEx_GetCurSel

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Cr�e une GUI
    $hGUI = GUICreate("ComboBoxEx Set Cur Sel", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 100, 200)

    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 99
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", $x), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; D�finit Cur Sel
    _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 99, 1))

    ; Obtient Cur Sel
    MsgBox($MB_SYSTEMMODAL, "Information", "Current Sel: " & _GUICtrlComboBoxEx_GetCurSel($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example