UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetExtendedUI

S�lectionne l'interface utilisateur par d�faut ou l'interface utilisateur �tendue

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetExtendedUI ( $hWnd [, $bExtended = False] )

Param�tres

$hWnd Handle du contr�le
$bExtended [optionnel] Indique si le combo box utilise l'extension

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarques

Par d�faut, la touche F4 ouvre ou ferme la liste et la fl�che vers le bas modifie la s�lection courante.

Dans une Combobox avec l'interface utilisateur avanc�e, la touche F4 est d�sactiv�e et la fl�che vers le bas ouvre la liste d�roulante.

En relation

_GUICtrlComboBoxEx_GetExtendedUI

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Cr�e une GUI
    $hGUI = GUICreate("ComboBoxEx Set Extended UI", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    ; D�finit Extended UI
    _GUICtrlComboBoxEx_SetExtendedUI($hCombo, True)

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contr�le m�mo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite