UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetItemEx

D�finit une partie ou tous les attributs d'un �l�ment

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItemEx ( $hWnd, ByRef $tItem )

Param�tres

$hWnd Handle du contr�le
$tItem Une structure $tagCOMBOBOXEXITEM

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarque

Pour d�finir les attributs d'un �l�ment d�finissez le membre de l'�l�ment de la structure $tagCOMBOBOXEXITEM avec l'index de l'�l�ment.
Pour un �l�ment, vous pouvez d�finir les membres Image, SelectedImage, OverlayImage, Ident, et Param de la structure $tagCOMBOBOXEXITEM.

En relation

$tagCOMBOBOXEXITEM, _GUICtrlComboBoxEx_GetItemEx, _GUICtrlComboBoxEx_SetItem

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $iImage, $tItem, $hCombo

    ; Cr�e une GUI
    $hGUI = GUICreate("ComboBoxEx Set ItemEx", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Modiifie l'�l�ment 2
    MsgBox($MB_SYSTEMMODAL, "Information", "Changing item 2")
    $tItem = DllStructCreate($tagCOMBOBOXEXITEM)
    DllStructSetData($tItem, "Mask", $CBEIF_INDENT)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "Indent", 2)

    _GUICtrlComboBoxEx_SetItemEx($hCombo, $tItem)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example