UDF > GUI > GuiEdit >

_GUICtrlEdit_GetRECTEx

Retourne une structure du rectangle de mise en forme d'un contr�le d'�dition

#include <GuiEdit.au3>
_GUICtrlEdit_GetRECTEx ( $hWnd )

Param�tre

$hWnd ID/handle du contr�le

Valeur de retour

Retourne une structure $tagRECT qui recoit le rectangle de mise en forme du contr�le d'�dition.

Remarque

Sous certaines conditions, _GUICtrlEdit_GetRECT() pourrait ne pas retourner les valeurs exactes que
_GUICtrlEdit_SetRECTEx() a d�finies, elles seront � peu pr�s correctes, mais elles pourront �tre erron�es de quelques pixels.

En relation

$tagRECT, _GUICtrlEdit_GetRECT

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[6] = [50, 130, 210, 290, 378, -1], $tRECT

    ; Cr�e une GUI
    $hGUI = GUICreate("Edit Get RECTEx", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 5, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($hStatusBar, "Rect")
    GUISetState(@SW_SHOW)

    ; Obtient RectEx
    $tRECT = _GUICtrlEdit_GetRECTEx($idEdit)
    DllStructSetData($tRECT, "Left", DllStructGetData($tRECT, "Left") + 10)
    DllStructSetData($tRECT, "Top", DllStructGetData($tRECT, "Top") + 10)
    DllStructSetData($tRECT, "Right", DllStructGetData($tRECT, "Right") - 10)
    DllStructSetData($tRECT, "Bottom", DllStructGetData($tRECT, "Bottom") - 10)

    ; D�finit RectEx
    _GUICtrlEdit_SetRECTEx($idEdit, $tRECT)

    ; Ajoute le texte
    _GUICtrlEdit_AppendText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Obtient RectEx
    $tRECT = _GUICtrlEdit_GetRECTEx($idEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Left: " & DllStructGetData($tRECT, "Left"), 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Topt: " & DllStructGetData($tRECT, "Top"), 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Right: " & DllStructGetData($tRECT, "Right"), 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Bottom: " & DllStructGetData($tRECT, "Bottom"), 4)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example