UDF > GUI > GuiEdit >

_GUICtrlEdit_SetModify

D�finit ou efface l'indicateur de modification

#include <GuiEdit.au3>
_GUICtrlEdit_SetModify ( $hWnd, $bModified )

Param�tres

$hWnd ID/handle du contr�le
$bModified Sp�cifie la nouvelle valeur de l'indicateur de modification:
    True - Indique que le texte a �t� modifi�.
    False - Indique qu'il n'a pas �t� modifi�.

Valeur de retour

Aucune.

Remarque

Le syst�me efface automatiquement l'indicateur de modification en le mettant � 0 lorsque le contr�le est cr��.
Si l'utilisateur modifie le texte du contr�le, le syst�me d�finit l'indicateur � une valeur non nulle.
Vous pouvez utiliser _GUICtrlEdit_GetModify() pour r�cup�rer l'�tat courant de l'indicateur.

En relation

_GUICtrlEdit_CanUndo, _GUICtrlEdit_GetModify

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[4] = [120, 248, 378, -1]

    ; Cr�e une GUI
    $hGUI = GUICreate("Edit Set Modify", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 3, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; D�finit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Ajoute le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit) * -1)

    ; Obtient le flag modifi�
    _GUICtrlStatusBar_SetText($hStatusBar, "Modified: " & _GUICtrlEdit_GetModify($idEdit), 2)

    MsgBox($MB_SYSTEMMODAL, "Information", "Set Modify Flag")
    ; D�finit le flag modifi�
    _GUICtrlEdit_SetModify($idEdit, True)

    ; Obtient le flag modifi�
    _GUICtrlStatusBar_SetText($hStatusBar, "Modified: " & _GUICtrlEdit_GetModify($idEdit), 2)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example