UDF > GUI > GuiListView >

_GUICtrlListView_GetGroupRect

Obtient le rectangle pour un groupe donn�

#include <GuiListView.au3>
_GUICtrlListView_GetGroupRect ( $hWnd, $iGroupID [, $iGet = $LVGGR_GROUP] )

Param�tres

$hWnd ID/handle du contr�le
$iGroupID ID qui sp�cifie le groupe dont les informations sont � r�cup�rer
$iGet [optionnel] Flag pour pr�ciser les coordonn�es du rectangle � obtenir, peut prendre l'une des valeurs suivantes:
    $LVGGR_GROUP - Coordonn�es de groupe entier d�velopp�
    $LVGGR_HEADER - Coordonn�es de l'en-t�te uniquement (groupe d�velopp�)
    $LVGGR_LABEL - Coordonn�es de l'�tiquette seulement
    $LVGGR_SUBSETLINK - Coordonn�es du lien du sous-ensemble seulement (balisage sous-ensemble)

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Coordonn�e x du coin sup�rieur gauche du rectangle
    [1] - Coordonn�e y du coin sup�rieur gauche du rectangle
    [2] - Coordonn�e x du coin inf�rieur droit du rectangle
    [3] - Coordonn�e y du coin inf�rieur droit du rectangle

Remarque

Windows Vista ou une version ult�rieure

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $hImage, $idListview

    GUICreate("ListView Get Group Info", 400, 300)

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Charge les images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des �l�ments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Construit des groupes
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1", 1)
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    ; Obtient le rectangle du Groupe d'ID 2
    $aInfo = _GUICtrlListView_GetGroupRect($idListview, 2)
    MsgBox($MB_SYSTEMMODAL, "Information", "Rect: " & @CRLF & _
            @TAB & "Left..: " & $aInfo[0] & @CRLF & _
            @TAB & "Top...: " & $aInfo[1] & @CRLF & _
            @TAB & "Right.: " & $aInfo[2] & @CRLF & _
            @TAB & "Bottom: " & $aInfo[3])

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example