UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_IsModified

Obtient l'�tat de l'indicateur de modification d'un contr�le RichEdit

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_IsModified ( $hWnd )

Param�tre

$hWnd Handle du contr�le

Valeur de retour

Succ�s: Retourne True ou False.
�chec: D�finit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

Le syst�me d�finit automatiquement l'indicateur de modification � False lorsque le contr�le est cr��.
Si le texte du contr�le est modifi�, soit par l'utilisateur soit par programmation, le syst�me d�finit l'indicateur � True. Appelez _GUICtrlRichEdit_SetModified() pour activer ou effacer l'indicateur.

En relation

_GUICtrlRichEdit_GetText, _GUICtrlRichEdit_SetModified

Voir aussi

Consultez EM_GETMODIFY dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    Report("�tat initial apr�s cr�ation")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Un paragraphe")
                    Report("Du texte a �t� ajout�")
                Case 2
                    _GUICtrlRichEdit_SetModified($g_hRichEdit, False)
                    Report("Apr�s effacement du flag de modification")
                Case 3
                    GUICtrlSetData($g_idLblMsg, "Tapez du texte puis cliquez sur Next")
                Case 4
                    Report("Apr�s la saisie")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; N�cessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "L'�tat du flag est " & _GUICtrlRichEdit_IsModified($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report