UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetCharBkColor

D�finit la couleur de fond du texte s�lectionn� ou, � d�faut de s�lection, la couleur de fond du texte ins�r� au point d'insertion

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetCharBkColor ( $hWnd [, $iBkColor = Default] )

Param�tres

$hWnd Handle du contr�le
$iBkColor [optionnel] Une des valeurs suivantes:
Un nombre - une valeur COLORREF
Le mot-cl� Default - la couleur du syst�me (par d�faut)

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
1021 - $iColor : pas 2 points-virgules
1022 - $iColor : valeur non comprise entre 0 et 100
1023 - $iColor : caract�re invalide

Remarque

Si vous avez besoin de cr�er une valeur COLORREF � partir d'un tableau de couleur, utilisez _ColorSetCOLORREF(), pas _ColorSetRGB().

En relation

_GUICtrlRichEdit_GetCharBkColor

Voir aussi

Consultez EM_SETCHARFORMAT dans la librairie MSDN.

Exemple

#include <Color.au3>
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $idBtnNext, $iStep = 0, $iMsg
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Ceci est un test.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 60, 30)
    GUISetState(@SW_SHOW)

    $iMsg = GUIGetMsg()
    While  $iMsg <> $GUI_EVENT_CLOSE 
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    Report("1. Param�tre initial")
                Case 2
                    _GUICtrlRichEdit_SetCharBkColor($g_hRichEdit, Dec('00FF00'))
                    Report("2. Param�trage maintenant")
                Case 3
                    _GUICtrlRichEdit_SetSel($g_hRichEdit, 1, 5)
                    _GUICtrlRichEdit_SetCharBkColor($g_hRichEdit, Dec('8888FF'))
                    Report("3. Contexte de quelques caract�res modifi�s")
                Case 4
                    ; Sauve le texte dans un fichier sur le bureau de sorte que vous puissiez regarder les param�tres dans Word
                    _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                    GUICtrlSetData($g_idLblMsg, "4. Sauv� dans le fichier gcre.rtf sur le bureau ")
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; N�cessaire si le script se bloque
    GUIDelete()
EndFunc   ;==>Example

Func Report($sMsg)
    Local $iColor = _GUICtrlRichEdit_GetCharBkColor($g_hRichEdit)
    Local $aRet = _ColorGetRGB($iColor)
    $sMsg &= @CRLF & @CRLF & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " BkColor=0x" & Hex ($iColor)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report