UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_SetEventMask

Sp�cifie quels messages de notification sont envoy�s � la fen�tre parent

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetEventMask ( $hWnd, $iEventMask )

Param�tres

$hWnd Handle du contr�le
$iEventMask Combinaison BitOR de:
    $ENM_CHANGE - Envoie des notifications $EN_CHANGE (l'utilisateur peut avoir modifi� le texte)
    $ENM_CORRECTTEXT - Envoie des notifications $EN_CORRECTTEXT (la fen�tre parent peut avoir annul� la correction du texte)
    $ENM_DRAGDROPDONE - Envoie des notifications $EN_DRAGDROPDONE (une op�ration Glisser-d�poser est termin�e)
    $ENM_DROPFILES - Envoie des notifications $EN_DROPFILES (l'utilisateur tente de d�poser des fichiers dans le contr�le)
    $ENM_KEYEVENTS - envoie des notifications $EN_MSGFILTER pour les �v�nements de clavier
    $ENM_LINK - Envoie des notifications $EN_LINK lorsque le pointeur de la souris est sur le texte qui a les caract�res d'attribut Link et lorsque l'utilisateur clique avec la souris [2.0+]
    $ENM_MOUSEEVENTS - envoie des notifications $EN_MSGFILTER pour les �v�nements de la souris vers la fen�tre parente
    $ENM_OBJECTPOSITIONS - envoie des notifications $EN_OBJECTPOSITIONS lorsque le contr�le lit dans les objets
    $ENM_PROTECTED - Envoie des notifications $EN_PROTECTED lorsque l'utilisateur tente de modifier des caract�res qui ont l'attribut Protected
    $ENM_REQUESTRESIZE - Envoie des notifications $EN_REQUESTRESIZE lorsque le contenu du contr�le est plus petit ou plus grand que la taille de la fen�tre du contr�le
    $ENM_SCROLL - Envoie des notifications $EN_HSCROLL et $EN_VSCROLL lorsque l'utilisateur clique sur la barre de d�filement horizontale/verticale
    $ENM_SCROLLEVENTS - envoie des notifications EN_MSGFILTER pour des �v�nements de molette de la souris
    $ENM_SELCHANGE - Envoie des notifications EN_SELCHANGE quand la s�lection change
    $ENM_UPDATE - Envoie des notifications $EN_UPDATE quand un contr�le est en train de se redessiner
ou
    $ENM_NONE - D�sactive l'envoi des messages de notification � la fen�tre parent

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0.
@error: 101 - $hWnd n'est pas un handle
102 - $iEventMask n'est pas un nombre

Remarques

Le nombre entre parenth�ses indique quelles versions masquent les param�tres � appliquer.

$ENM_IMECHANGE s'applique uniquement aux versions en langues asiatiques de Windows.

Des notifications $EN_UPDATE sont toujours envoy�s, sauf quand 4.0 �mule 1.0

En relation

_GUICtrlRichEdit_AutoDetectURL

Voir aussi

Consultez EM_SETEVENTMASK dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_hRichEdit, $g_idMnu, $g_idMnuUndo, $g_idMnuRedo, $g_idMnuCut, $g_idMnuCopy
Global $g_idMnuPaste, $g_idMnuPasteSpl

Example()

Func Example()
    Local $hGui, $idMnuPasteSplRTF, $idMnuPasteSplwObjs
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($g_hRichEdit, ReadBmpToRtf(FindFirstBMP()) & @CRLF)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    $g_idMnu = GUICtrlCreateContextMenu(GUICtrlCreateDummy())
    $g_idMnuUndo = GUICtrlCreateMenuItem("Undo", $g_idMnu)
    $g_idMnuRedo = GUICtrlCreateMenuItem("Redo", $g_idMnu)
    GUICtrlCreateMenuItem("", $g_idMnu)
    $g_idMnuCut = GUICtrlCreateMenuItem("Cut", $g_idMnu)
    $g_idMnuCopy = GUICtrlCreateMenuItem("Copy", $g_idMnu)
    $g_idMnuPaste = GUICtrlCreateMenuItem("Paste", $g_idMnu)
    $g_idMnuPasteSpl = GUICtrlCreateMenu("Paste Special", $g_idMnu)
    $idMnuPasteSplRTF = GUICtrlCreateMenuItem("RTF only", $g_idMnuPasteSpl)
    $idMnuPasteSplwObjs = GUICtrlCreateMenuItem("With objects", $g_idMnuPasteSpl)
    _GUICtrlRichEdit_SetEventMask($g_hRichEdit, $ENM_MOUSEEVENTS)

    Local $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE 
        Switch $iMsg
            Case $g_idMnuUndo
                _GUICtrlRichEdit_Undo($g_hRichEdit)
            Case $g_idMnuRedo
                _GUICtrlRichEdit_Redo($g_hRichEdit)
            Case $g_idMnuCut
                _GUICtrlRichEdit_Cut($g_hRichEdit)
            Case $g_idMnuCopy
                _GUICtrlRichEdit_Copy($g_hRichEdit)
            Case $g_idMnuPaste
                _GUICtrlRichEdit_Paste($g_hRichEdit)
            Case $idMnuPasteSplRTF
                _GUICtrlRichEdit_PasteSpecial($g_hRichEdit, False)
            Case $idMnuPasteSplwObjs
                _GUICtrlRichEdit_PasteSpecial($g_hRichEdit, True)
        EndSwitch
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; N�cessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam
    Local $hWndFrom, $iCode, $tNMHDR, $tMsgFilter, $hMenu
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    If $hWndFrom = $g_hRichEdit Then
        If $iCode = $EN_MSGFILTER Then
            $tMsgFilter = DllStructCreate($tagMSGFILTER, $lParam)
            If DllStructGetData($tMsgFilter, "msg") = $WM_RBUTTONUP Then
                $hMenu = GUICtrlGetHandle($g_idMnu)
                SetMenuTexts($hWndFrom, $hMenu)
                _GUICtrlMenu_TrackPopupMenu($hMenu, $hWnd)
            EndIf
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func SetMenuTexts($hWnd, $hMenu)
    Local $bState
    If _GUICtrlRichEdit_CanUndo($hWnd) Then
        _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuUndo, True, False)
        _GUICtrlMenu_SetItemText($hMenu, $g_idMnuUndo, "Undo: " & _GUICtrlRichEdit_GetNextUndo($hWnd), False)
    Else
        _GUICtrlMenu_SetItemText($hMenu, $g_idMnuUndo, "Undo", False)
        _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuUndo, False, False)
    EndIf
    If _GUICtrlRichEdit_CanRedo($hWnd) Then
        _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuRedo, True, False)
        _GUICtrlMenu_SetItemText($hMenu, $g_idMnuRedo, "Redo: " & _GUICtrlRichEdit_GetNextRedo($hWnd), False)
    Else
        _GUICtrlMenu_SetItemText($hMenu, $g_idMnuRedo, "Redo", False)
        _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuRedo, False, False)
    EndIf
    $bState = _GUICtrlRichEdit_IsTextSelected($hWnd)
    _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuCut, $bState, False)
    _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuCopy, $bState, False)

    _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuPaste, _GUICtrlRichEdit_CanPaste($hWnd))

    _GUICtrlMenu_SetItemEnabled($hMenu, $g_idMnuPasteSpl, _GUICtrlRichEdit_CanPasteSpecial($hWnd), False)
EndFunc   ;==>SetMenuTexts

Func ReadBmpToRtf($sBmpFilspc)
    Local $hFile, $sRtf
    $hFile = FileOpen($sBmpFilspc, 16)
    If FileRead($hFile, 2) <> "0x424D" Then Return SetError(1, 0, "")
    FileRead($hFile, 12)
    $sRtf = '{\rtf1{\pict\dibitmap '& Hex(FileRead($hFile)) & '}}'
    FileClose($hFile)
    Return $sRtf
EndFunc   ;==>ReadBmpToRtf

Func FindFirstBMP($sPath = @WindowsDir)
    Local $hFind, $sBmpFilspc
    $hFind = FileFindFirstFile($sPath & "\*.bmp")
    $sBmpFilspc = FileFindNextFile($hFind)
    FileClose($hFind)
    Return $sPath & "\" & $sBmpFilspc
EndFunc   ;==>FindFirstBMP